NAME

SVG - Perl extension for generating Scalable Vector Graphics (SVG) documents

VERSION

Version 0.50, 12 October 2001

METHODS

C<attrib>, C<animate>, C<cdata>, C<circle>, C<defs>, C<desc>,
C<ellipse>, C<fe>, C<get_path>, C<group>, C<image>, C<line>,
C<mouseaction>, C<new>, C<path>, C<polygon>, C<rectangle>, C<script>,
C<style>, C<SVG>, C<text>, C<title>, C<use>, C<xmlify>

SYNOPSIS

  #!/usr/bin/perl -w
  use strict;
  use SVG;

  # create an SVG object
  my $svg= SVG->new(width=>200,height=>200);

  # use explicit element constructor to generate a group element
  my $y=$svg->group(
      id    => 'group_y',
      style => { stroke=>'red', fill=>'green' }
  );

  # add a circle to the group
  $y->circle(cx=>100, cy=>100, r=>50, id=>'circle_in_group_y');

  # or, use the generic 'tag' method to generate a group element by name
  my $z=$svg->tag('g',
                  id    => 'group_z',
                  style => {
                      stroke => 'rgb(100,200,50)',
                      fill   => 'rgb(10,100,150)'
                  }
              );

  # create and add a circle using the generic 'tag' method
  $z->tag('circle', cx=>50, cy=>50, r=>100, id=>'circle_in_group_z');

  # create an anchor on a rectangle within a group within the group z
  my $k = $z->anchor(
      id      => 'anchor_k',
      -href   => 'http://test.hackmare.com/',
      -target => 'new_window_0'
  )->rectangle(
      x     => 20, y      => 50,
      width => 20, height => 30,
      rx    => 10, ry     => 5,
      id    => 'rect_k_in_anchor_k_in_group_z'
  );

  # now render the SVG object, implicitly use svg namespace
  print $svg->xmlify;

  # or, explicitly use svg namespace and generate a document with its own DTD
  print $svg->xmlify(-namespace=>'svg');

  # or, explicitly use svg namespace and generate an in-line docunent
  print $svg->xmlify(
      namespace => "svg",
      ns_url    => "http://www.w3.org/2000/svg", # SVG namespace
      xmlns     => "http://roasp.com/",          # Document namespace
      -inline   => 1
  );

DESCRIPTION

SVG is a 100% Perl module which generates a nested data structure containing the DOM representation of an SVG (Scalable Vector Graphics) image. Using SVG, you can generate SVG objects, embed other SVG instances into it, access the DOM object, create and access javascript, and generate SMIL animation content.

General Steps to generating an SVG document

Generating SVG is a simple three step process:

1 The first step is to construct a new SVG object with new.
2 The second step is to call element constructors to create SVG elements. Examples of element constructors are circle and path.
3 The third and last step is to render the SVG object into XML using the xmlify method.

The xmlify method takes a number of optional arguments that control how SVG renders the object into XML, and in particular determine whether a stand-alone SVG document or an inline SVG document fragment is generated:

-stand-alone: A complete SVG document with its own associated DTD. A namespace for the SVG elements may be optionally specified.
-in-line: An in-line SVG document fragment with no DTD that be embedded within other XML content. As with stand-alone documents, an alternate namespace may be specified.

No XML content is generated until the third step is reached. Up until this point, all constructed element definitions reside in a DOM-like data structure from which they can be accessed and modified.

EXPORTS

None

AUTHOR

Ronan Oger, ronan@roasp.com

Methods

SVG provides both explicit and generic element constructor methods. Explicit generators are generally (with a few exceptions) named for the element they generate.

All element constructors take a hash of element attributes and instructions; element attributes such as 'id' are passed by name, while instructions for the method (such as the type of an element that supports multiple alternate forms) are passed preceded by a hyphen, e.g '-type'. Both types may be freely intermixed; see the fe method and code examples througout the documentation for more examples.

new (constructor)

$svg = SVG->new(%attributes)

Creates a new SVG object.

xmlify

$xmlstring = $svg->xmlify(%attributes)

Returns xml representation of svg document.

XML Declaration

B<Name>           B<Default Value>
version           '1.0'
encoding          'UTF-8'
standalone        'yes'
namespace         'svg'                - namespace for elements
xmlns (inline)    'http://example.org' - see <parent> tag below
ns_url (inline)   'the url of the xml' - see <parent> tag below
-inline           '0' - If '1', then this is an inline document.
identifier        '-//W3C//DTD SVG 1.0//EN';
dtd (standalone)  'http://www.w3.org/TR/2001/REC-SVG-20010904/DTD/svg10.dtd'

Parent tag:

<parent xmlns="[xmlns]" xmlns:[namespace]="[ns_url]">

For example:

print $svg->xmlify(
    namespace => "mysvg",
    ns_url    => "http://www.w3.org/2000/svg", # SVG namespace
    xmlns     => "http://roasp.com/",          # Document namespace
    -inline   => 1
);

Output:

<parent xmlns="http://roasp.com" xmlns:mysvg="http://www.w3.org/2000/svg">
<mysvg:svg>
   ...
</mysvg:svg>

tag (alias: element)

$tag = $svg->tag($name, %attributes)

Generic element generator. Creates the element named $name with the attributes specified in %attributes. This method is the basis of most of the explicit element generators.

Example:

my $tag = $svg->tag('g', transform=>'rotate(-45)');

anchor

$tag = $svg->anchor(%attributes)

Generate an anchor element. Anchors are put around objects to make them 'live' (i.e. clickable). It therefore requires a drawn object or group element as a child.

Example:

    # generate an anchor	
    $tag = $svg->anchor(
        -href=>'http://here.com/some/simpler/svg.svg'
    );
    # add a circle to the anchor. The circle can be clicked on.
    $tag->circle(cx=>10,cy=>10,r=>1);

    # more complex anchor with both URL and target
    $tag = $svg->anchor(
	-href   => 'http://somewhere.org/some/other/page.html',
	-target => 'new_window'
    );

circle

$tag = $svg->circle(%attributes)

Draw a circle at (cx,cy) with radius r.

Example:

my $tag = $svg->circlecx=>4, cy=>2, r=>1);

ellipse

$tag = $svg->ellipse(%attributes)

Draw an ellipse at (cx,cy) with radii rx,ry.

Example:

my $tag = $svg->ellipse(
    cx=>10, cy=>10,
    rx=>5, ry=>7,
    id=>'ellipse',
    style=>{
        'stroke'=>'red',
        'fill'=>'green',
        'stroke-width'=>'4',
        'stroke-opacity'=>'0.5',
        'fill-opacity'=>'0.2'
    }
);

rectangle (alias: rect)

$tag = $svg->rectangle(%attributes)

Draw a rectangle at (x,y) with width 'width' and height 'height' and side radii 'rx' and 'ry'.

Example:

$tag = $svg->rectangle(
    x=>10, y=>20,
    width=>4, height=>5,
    rx=>5.2, ry=>2.4,
    id=>'rect_1'
);

image

$tag = $svg->image(%attributes)

Draw an image at (x,y) with width 'width' and height 'height' linked to image resource '-href'. See also use.

Example:

$tag = $svg->image(
    x=>100, y=>100,
    width=>300, height=>200,
    '-href'=>"image.png", #may also embed SVG, e.g. "image.svg"
    id=>'image_1'
);

Output:

<image xlink:href="image.png" x="100" y="100" width="300" height="200"/>

use

$tag = $svg->use(%attributes)

Retrieve the content from an entity within an SVG document and apply it at (x,y) with width 'width' and height 'height' linked to image resource '-href'.

Example:

$tag = $svg->use(
    x=>100, y=>100,
    width=>300, height=>200,
    '-href'=>"pic.svg#image_1",
    id=>'image_1'
);

Output:

<use xlink:href="pic.svg#image_1" x="100" y="100" width="300" height="200"/>

According to the SVG specification, the 'use' element in SVG can point to a single element within an external SVG file.

polygon

$tag = $svg->polygon(%attributes)

Draw an n-sided polygon with vertices at points defined by a string of the form 'x1,y1,x2,y2,x3,y3,... xy,yn'. The get_path method is provided as a convenience to generate a suitable string from coordinate data.

Example:

# a five-sided polygon
my $xv = [0,2,4,5,1];
my $yv = [0,0,2,7,5];

$points = $a->get_path(
    x=>$xv, y=>$yv,
    -type=>'polygon'
);

$c = $a->polygon(
    %$points,
    id=>'pgon1',
    style=>\%polygon_style
);

SEE ALSO:

C<polyline>, C<path>, C<get_path>.

polyline

$tag = $svg->polyline(%attributes)

Draw an n-point polyline with points defined by a string of the form 'x1,y1,x2,y2,x3,y3,... xy,yn'. The get_path method is provided as a convenience to generate a suitable string from coordinate data.

Example:

# a 10-pointsaw-tooth pattern
my $xv = [0,1,2,3,4,5,6,7,8,9];
my $yv = [0,1,0,1,0,1,0,1,0,1];

$points = $a->get_path(
    x=>$xv, y=>$yv,
    -type=>'polyline',
    -closed=>'true' #specify that the polyline is closed.
);

my $tag = $a->polyline (
    %$points,
    id=>'pline_1',
    style=>{
        'fill-opacity'=>0,
        'stroke-color'=>'rgb(250,123,23)'
    }
);

line

$tag = $svg->line(%attributes)

Draw a straight line between two points (x1,y1) and (x2,y2).

Example:

my $tag = $svg->line(
    id=>'l1',
    x1=>0, y1=>10,
    x2=>10, y2=>0
);

To draw multiple connected lines, use polyline.

text

$text = $svg->text(%attributes)->cdata();

$text = $svg->text(%attributes,-cdata=>'textstring');

define the container for a text string to be drawn in the image.

Example:

my $text1 = $svg->text(
    id=>'l1', x=>10, y=>10
)->cdata('hello, world');

my $text2 = $svg->text(id=>'l1', x=>10, y=>10, -cdata=>'hello, world');

SEE ALSO:

C<desc>, C<cdata>.

title

$tag = $svg->title(%attributes)

Generate the title of the image.

Example:

my $tag = $svg->title(id=>'root-title')->cdata('This is the title');

desc

$tag = $svg->desc(%attributes)

Generate the description of the image.

Example:

my $tag = $svg->desc(id=>'root-desc')->cdata('This is a description');

script

$tag = $svg->script(%attributes)

Generate a script container for dynamic (client-side) scripting using ECMAscript, Javascript or other compatible scripting language.

Example:

my $tag = $svg->script(-type=>"text/ecmascript");

# populate the script tag with cdata
# be careful to manage the javascript line ends.
# qq|text| or qq§text§ where text is the script 
# works well for this.

$tag->cdata(qq|function d(){
    //simple display function
    for(cnt = 0; cnt < d.length; cnt++)
        document.write(d[cnt]);//end for loop
    document.write("<BR>");//write a line break
  }|
);

path

$tag = $svg->path(%attributes)

Draw a path element. The path vertices may be imputed as a parameter or calculated usingthe get_path method.

Example:

# a 10-pointsaw-tooth pattern drawn with a path definition
my $xv = [0,1,2,3,4,5,6,7,8,9];
my $yv = [0,1,0,1,0,1,0,1,0,1];

$points = $a->get_path(
    x => $xv,
    y => $yv,
    -type   => 'path',
    -closed => 'true'  #specify that the polyline is closed
);

$tag = $svg->path(
    %$points,
    id    => 'pline_1',
    style => {
        'fill-opacity' => 0,
        'fill-color'   => 'green',
        'stroke-color' => 'rgb(250,123,23)'
    }
);

SEE ALSO:

L<get_path>.

get_path

$path = $svg->get_path(%attributes)

Returns the text string of points correctly formatted to be incorporated into the multi-point SVG drawing object definitions (path, polyline, polygon)

Input: attributes including:

-type     = path type (path | polyline | polygon)
x         = reference to array of x coordinates
y         = reference to array of y coordinates

Output: a hash reference consisting of the following key-value pair:

points    = the appropriate points-definition string
-type     = path|polygon|polyline
-relative = 1 (define relative position rather than absolute position)
-closed   = 1 (close the curve - path and polygon only)

Example:

   #generate an open path definition for a path.
   my ($points,$p);
   $points = $svg->get_path(x=&gt\@x,y=&gt\@y,-relative=&gt1,-type=&gt'path');

   #add the path to the SVG document
   my $p = $svg->path(%$path, style=>\%style_definition);

   #generate an closed path definition for a a polyline.
   $points = $svg->get_path(
       x=>\@x,
       y=>\@y,
       -relative=>1,
       -type=>'polyline',
       -closed=>1
   ); # generate a closed path definition for a polyline

   # add the polyline to the SVG document
   $p = $svg->polyline(%$points, id=>'pline1');

Aliases: get_path set_path

animate

animate(%attributes)

Generate an SMIL animation tag. This is allowed within any nonempty tag. Refer\ to the W3C for detailed information on the subtleties of the animate SMIL commands.

Inputs: -method = Transform | Motion | Color

group

$tag = $svg->group(%attributes)

Define a group of objects with common properties. groups can have style, animation, filters, transformations, and mouse actions assigned to them.

Example:

$tag = $svg->group(
    id        => 'xvs000248',
    style     => {
        'font'      => [ qw( Arial Helvetica sans ) ],
        'font-size' => 10,
        'fill'      => 'red',
    },
    transform => 'rotate(-45)'
);

defs

$tag = $svg->defs(%attributes)

define a definition segment. A Defs requires children when defined using SVG.pm Example:

$tag = $svg->defs(id  =>  'def_con_one',);

style

$svg->style(%styledef)

Sets/Adds style-definition for the following objects being created.

Style definitions apply to an object and all its children for all properties for which the value of the property is not redefined by the child.

mouseaction

$svg->mouseaction(%attributes): Sets/Adds mouse action definitions for tag
$svg->attrib($name, $value): Sets/Adds mouse action definitions.
$svg->attrib $name, $value
$svg->attrib $name, \@value
$svg->attrib $name, \%value: Sets/Replaces attributes for a tag.

cdata

$svg->cdata($text)

Sets cdata to $text. SVG.pm allows you to set cdata for any tag. If the tag is meant to be an empty tag, SVG.pm will not complain, but the rendering agent will fail. In the SVG DTD, cdata is generally only meant for adding text or script content.

Example:

$svg->text(
    style => {
        'font'      => 'Arial',
        'font-size' => 20
    })->cdata('SVG.pm is a perl module on CPAN!');

my $text = $svg->text(style=>{'font'=>'Arial','font-size'=>20});
$text->cdata('SVG.pm is a perl module on CPAN!');

Result:

E<lt>text style="font: Arial; font-size: 20" E<gt>SVG.pm is a perl module on CPAN!E<lt>/text E<gt>

SEE ALSO:

C<desc>, C<title>, C<text>, C<script>.

filter

$tag = $svg->filter(%attributes)

Generate a filter. Filter elements contain fe filter sub-elements.

Example:

my $filter = $svg->filter(
    filterUnits=>"objectBoundingBox",
    x=>"-10%",
    y=>"-10%",
    width=>"150%",
    height=>"150%",
    filterUnits=>'objectBoundingBox'
);

$filter->fe();

SEE ALSO:

C<fe>.

fe

$tag = $svg->fe(-type=>'type', %attributes)

Generate a filter sub-element. Must be a child of a filter element.

Example:

my $fe = $svg->fe(
    -type     => 'DiffuseLighting'  # required - element name omiting 'fe'
    id        => 'filter_1',
    style     => {
        'font'      => [ qw(Arial Helvetica sans) ],
        'font-size' => 10,
        'fill'      => 'red',
    },
    transform => 'rotate(-45)'
);

Note that the following filter elements are currently supported:

feBlend
feColorMatrix
feComponentTransfer
feComposite
feConvolveMatrix
feDiffuseLighting
feDisplacementMap
feDistantLight
feFlood
feFuncA
feFuncB
feFuncG
feFuncR
feGaussianBlur
feImage
feMerge
feMergeNode
feMorphology
feOffset
fePointLight
feSpecularLighting
feSpotLight
feTile
feTurbulence

SEE ALSO:

C<filter>.

pattern

$tag = $svg->pattern(%attributes)

Define a pattern for later reference by url.

Example:

my $pattern = $svg->pattern(
    id     => "Argyle_1",
    width  => "50",
    height => "50",
    patternUnits        => "userSpaceOnUse",
    patternContentUnits => "userSpaceOnUse"
);

set

$tag = $svg->set(%attributes)

Set a definition for an SVG object in one section, to be referenced in other sections as needed.

Example:

my $set = $svg->set(
    id     => "Argyle_1",
    width  => "50",
    height => "50",
    patternUnits        => "userSpaceOnUse",
    patternContentUnits => "userSpaceOnUse"
);

stop

$tag = $svg->stop(%attributes)

Define a stop boundary for gradients

Example:

my $pattern = $svg->stop(
    id     => "Argyle_1",
    width  => "50",
    height => "50",
    patternUnits        => "userSpaceOnUse",
    patternContentUnits => "userSpaceOnUse"
);

$tag = $svg->gradient(%attributes)

Define a color gradient. Can be of type linear or radial

Example:

my $gradient = $svg->gradient(
    -type => "linear",
    id    => "gradient_1"
);

TO DO

The following elements have not yet been implemented as of this release:

altGlyph
altGlyphDef
altGlyphItem
clipPath
color-profile
cursor
definition-src
font-face-format
font-face-name
font-face-src
font-face-url
foreignObject
glyph
glyphRef
hkern
marker
mask
metadata
missing-glyph
mpath
pattern
switch
symbol
textPath
tref
tspan
view
vkern

Although these elements do not have an explicit constructor, they can be constructed using the generic element constructor tag.

59 POD Errors

The following errors were encountered while parsing the POD:

Around line 159: