NAME
XML::DOM::Lite - Lite Pure Perl XML DOM Parser Kit
SYNOPSIS
# Parser
use XML::DOM::Lite qw(Parser :constants);
$parser = Parser->new( %options );
$doc = Parser->parse($xmlstr);
$doc = Parser->parseFile('/path/to/file.xml');
# strip whitespace (can be about 30% faster)
$doc = Parser->parse($xml, whitespace => 'strip');
# rudimentary XPath support
$nlist = $doc->selectNodes('/xpath/expression');
$node = $doc->selectSingleNode('/xpath/expression');
# Document
$rootnode = $doc->documentElement;
$nodeWithId = $doc->getElementById("my_node_id");
$textnode = $doc->createTextNode("some text string");
$element = $doc->createElement("myTagName");
$xmlstr = $doc->xml;
# All Nodes
$copy = $node->cloneNode($deep);
$nodeType = $node->nodeType;
$parent = $node->parentNode;
$name = $node->nodeName;
# Element Nodes
$last = $node->lastChild;
$first = $node->firstChild;
$tag = $node->tagName;
$node->setAttribute("foo", $bar);
$foo = $node->getAttribute("foo");
$liveNodeList = $node->getElementsByTagName("child"); # deep
$node->insertBefore($newchild, $refchild);
$node->replaceChild($newchild, $refchild);
# Text Nodes
$nodeValue = $node->nodeValue;
$node->nodeValue("new text value");
# Processing Instruction Nodes
# CDATA Nodes
# Comments
$data = $node->nodeValue;
# NodeList
$item = $nodeList->item(42);
$index = $nodeList->nodeIndex($node);
$nlist->insertNode($newNode, $index);
$removed = $nlist->removeNode($node);
$length = $nlist->length; # OR scalar(@$nodeList)
# NodeIterator and NodeFilter
use XML::DOM::Lite qw(NodeIterator NodeFilter :constants);
$nfilt = NodeFilter->new(sub {
my $n = shift;
if ($n->tagName eq 'wantme') {
return FILTER_ACCEPT;
} elsif ($n->tagName eq 'skipme') {
return FILTER_SKIP;
} else {
return FILTER_REJECT;
}
});
$niter = NodeIterator->new($rootnode, SHOW_ELEMENT, $nfilt);
while (my $n = $niter->nextNode) {
# do stuff
}
# XPath
use XML::DOM::Lite qw(XPath);
$xp = XPath->new;
$nlist = $xp->evaluate('/path/to/*[@attr="value"]', $contextNode);
# Serializer
use XML::DOM::Lite qw(Serializer);
$serializer = Serializer->new;
$xmlout = $serializer->serializerToString($node);INTRODUCTION
Why Yet Another XML Parser?
Because the DOM standard was not made for Perl and lacks certain perlisms, and if you, like me, prefer a perlesque way of doing things, then the full DOM API can get a bit clunky.
Most of the time when dealing with XML DOM trees, I find myself doing a lot of traversal - and when doing so, I usually want my DOM tree to be a HASH ref with ARRAY refs of HASH refs (etc.) so that I can say :
foreach (@{$node->childNodes}) {
if ($_->nodeType & ELEMENT_NODE) {
# do stuff
}
}... or ...
@cdata = map {
$_->nodeValue if $_->nodeType eq TEXT_NODE
}, @{$node->childNodes};... or for attributes :
foreach (keys %{$node->attributes}) {
# do something
}Furthermore, maybe sometimes I want the value of an attribute to, temporarily, be something other than a string, so...
$node->setAttribute("sessionStash", $session->stash);Sometimes, I may want to Storable::freeze or YAML::Dump or DBM::Deep::put my DOM tree (or some part of it) without any XS bits getting in the way.
Other times, I may just not have Expat handy, and I want something that can munge a bit of XML into a usable data structure and still perform reasonably well.
Finally, and this is really how/why this module came to be, I may not feel like going the whole XSLT hog and simply prefer to treat each node as a subclassable data entity upon which I can call methods to make it transform itself.
And/Or any combination of the above.
DESCRIPTION
XML::DOM::Lite is designed to be a reasonably fast, highly portable, XML parser kit written in pure perl, implementing the DOM standard quite closely. To keep performance up and footprint down, certain DOM features are not supported such as comment, DOCTYPE nodes and processing instructions (these are simply parsed as text nodes). However, 90-99% of what most end up doing with XML can be done without these features.
The standard pattern for using the XML::DOM::Lite parser kit is to use XML::DOM::Lite qw(Parser :constants);
Available exports are : Parser, Node, NodeList, NodeIterator, NodeFilter, XPath, Document and the constants.
This is mostly for convenience, so that you can save your key-strokes for the fun stuff. Alternatively, to avoid polluting your namespace, you can simply : use XML::DOM::Lite::Parser; use XML::DOM::Lite::Constants qw(:all); # ... etc
Bitwise nodeType comparison
All nodeType comparisons are done with the bitwise `&' operator against the constants exported by XML::DOM::Constants (which is why it is customary to import the :constants tag) for performance reasons.
Parser Options
So far the only options which are supported involve white space stripping and normalization. The whitespace option value can be 'strip' or 'normalize'.
The 'strip' option removes whitespace at the beginning and end of XML tag. Thus, whitespace between tags is completely eliminated and whitespace at the beginning and end of text nodes is removed. If you are using inline tags, this will result in the removal of whitespace between text.
E.g the sequence "Sequence of <b>bold</b> and <i>italic</i> words" will be changed to 'Sequence ofboldanditalcwords'.
The 'normalize' option replaces all multiple tab, new line space characters with a single space character.
PERFORMANCE
Performance has been drastically improved as of version 0.4. We're seeing benchmark time improvements from 16 seconds to 3.6 seconds for 7500 nodes on a 2.8 GHz Celeron. This is due to a complete overhaul of the parser using the "shallow parsing" techniques and regular expressions documented on http://www.cs.sfu.ca/~cameron/REX.html
BUGS
Better error handling.
ACKNOWLEDGEMENTS
Thanks to: Robert Frank Robert D. Cameron
AUTHOR
Copyright (C) 2005 Richard Hundt <richard NO SPAM AT protea-systems.com>
LICENCE
This library is free software and may be used under the same terms as Perl itself.