NAME/НАИМЕНОВАНИЕ

perlre - регулярные выражения Perl

ОПИСАНИЕ

Эта страница описывает синтаксис регулярных выражений в Perl.

Если вы раньше не использовали регулярные выражения, то есть быстрое введение в perlrequick и более длинное в perlretut.

О том, как регулярные выражения используются в поиске по шаблону, а также различные примеры см. обсуждение m//, s///, qr// и ?? в "Regexp операторы заключения в кавычки" in perlop.

Модификаторы

Операторы поиска по шаблону имеют разные модификаторы. Модификаторы, которые относятся к интерпретации внутри регулярных выражений перечислены ниже. Модификаторы, которые изменяют путь регулярного выражения, использующегося в Perl, детализированы в "Regexp операторы заключения в кавычки" in perlop и "Внутренние детали парсинга конструкций в кавычках" in perlop.

m

Представляет строку поиска, как многострочную. Разрешает метасимволам ^ и $ привязываться к промежуточным символам \n, имеющимся в тексте.

s

Метасимволу "точка" разрешено соответствовать \n.

Используя вместе как /ms позволяет "." соответствовать любому символу включая новую строку а символы "^" и "$" становятся началом и концом всего буфера.

i

Игнорирует регистр символов при сопоставлении с образцом.

Если правила поиска локали включены, текущая карта символов берется из текущей локали для символов с кодом менее 255 и используются юникодные правила для больших кодовых точек. Однако совпадение, которое будет пересекать правила Unicode / не Unicode на границе (Ords 255/256) не удастся. См. perllocale.

Есть целый ряд символов Юникода, которым соответствуют несколько символов в /I Например, LATIN SMALL LIGATURE FI должна соответствовать последовательности /I Perl в настоящее время не в состоянии сделать это, когда многократные знаки находятся в образце поиска и расколоты между группировками, или когда один или больше определен количественно. Таким образом use charnames ':full'; #примечание переводчика

"\N{LATIN SMALL LIGATURE FI}" =~ /fi/i;          # найдет
"\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i;    # Не найдет!
"\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i;         # Не найдет!

# Ниже не будет соответствия, и не ясно, что было бы в $1 и $2
# будьте честны, если это произойдет
"\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i;      # Не найдет!

Perl не находит несколько символов в скобках (образующих класс), если только знак, который отображается на них прямо упоминается, и он не находит вообще, если класс символов инвертирован, что в противном случае могло бы быть очень запутанно. См. "Bracketed Character Classes" in perlrecharclass, and "Negation" in perlrecharclass.

x

Увеличивает читаемость вашего шаблона для поиска, разрешаются пробелы и комментарии. Подробности в "/x"

p

Сохраненные части строки, такие как ${^PREMATCH}, ${^MATCH}, и ${^POSTMATCH} доступны для использования после поиска по шаблону.

g и c

Глобальный поиск совпадений, и сохранение текущей позиции после неудачного поиска. В отличие от i, m, s и x,эти два флага влияют затрагиваем способ, которым regex используется, а не сам regex. См. ""Using regular expressions in Perl" (Использоывание регулярных выражений Perl)" in perlretut для получения большей информации о модификаторах g и c.

a, d, l и u

Эти модификаторы, все новые в 5.14, влияют при какая семантике кодировки (Unicode, и т.д.) используются, как описано ниже в L </модификаторы Кодировки>.}

Модификаторы регулярных выражений обычно описываются в документации, например,как " /x модификатор" несмотря на косую черту, разделителем может быть не только слэш. Модификаторы /imsxadlup могут также быть включены в пределах самого регулярного выражения, используя конструкцию (?...) , см. "Extended Patterns" ("Расширенные Образцы") ниже.

/x

/x говорит регулярному анализатору выражения игнорировать большую часть пробелов, перед которыми не стоит обратный слэш и не входящих в класс символов. Вы можете использовать это, чтобы разбить ваше регулярное выражение на части, чтобы сделать его более читаемым. Символ # также рассматривается как метасимвол, являющимся комментарием, как в обычном коде Perl. Это также означает, что если вы хотите реальный пробел или символ # в шаблоне поиска (вне класса характера, где они незатронуты /x), тогда вы должны будете или эскейпить их (используя наклонную черту влево или \Q...\E) или кодировать их используя восьмеричный, шестнадцатиричный или \N{} код. Взятые вместе, эти фичи (features) имеют большое значение для создания более читаемых регулярных выражений в Perl. Обратите внимание, что вы должны быть осторожны, чтобы не включать разделитель шаблона в комментарий --perl не имеет никакого способа узнать, что вы не намеревались закрыть шаблон раньше. См. удаление комментариев в C коде в perlop. Также отметим, что все внутри \Q...\E остается не зависимым от /x. И заметьте, что /x не влияет на интерпретацию пространства в пределах одной многосимвольной конструкции. Например, в \x{...}, независимо от модификатора /x, не может быть пробелов. То же самое для quantifier таких как {3} или {5,}. Аналогично, (?:...) не может иметь пробелов между (, ?, и :. В пределах любых разделителей для такой конструкции, позволенные пробелы не имеют силы из-за /x и зависят от конструкции. Например, \x{...} не должно быть пробелов, потому что шестнадцатеричные числа не имеют в себе пробелов. Но, у свойств Unicode (Unicode properties) могут быть пробелы, таким образом, в \p{...} могут быть пробелы, которые следуют за правилами Unicode, для которых см. "Properties accessible through \p{} and \P{}" in perluniprops (L <perluniprops/Свойства, доступные через \p{} и \P{}>)

Модификаторы Кодировки

/d, /u, /a, и /l, доступные, начиная с 5.14, называют модификаторами кодировки; они затрагивают семантику кодировки, используемую для регулярного выражения.

Модификаторы /d, /u, и /l вряд ли будут иметь большое применения вами, и таким образом, вы не должны о них очень волноваться. Они существуют для внутреннего использования Perl, так, чтобы сложные структуры данных регулярных выражений могли быть автоматически преобразованы в последовательную форму и позже точно воссозданы, включая все их нюансы. Но, так как Perl не может хранить все в тайне, и могут быть редкие случаи, где они полезны, они задокументированы здесь.

Модификатор /a, с другой стороны, может быть полезным. Его цель заключается в том, что он позволяет коду работать главным образом на данных ASCII, чтобы не иметь проблем с Unicode.

Кратко, /l задает кодировку, которая будет работать в любой <L>ocale во время выполнения поиска по шаблону.

/u задает кодировку Юникод.

/a также устанавливает набор символов для Юникода, но добавляет несколько ограничений ASCII-безопасного поиска.

/d является старым, проблематичным, перед-5.14 Нбором по умолчанию символов поведение. Используется только для этого старого поведения.

В любой момент времени только один из этих модификаторов действует. Их существование позволяет Perl сохранить первоначально скомпилированное поведение регулярного выражения, независимо от действий правил, когда оно действительно выполняется. И, если он интерполируется в больших регекс, оригинал в правила продолжают применяться к нему и только к нему.

/l и /u модификаторы автоматически выбираются для регулярных выражений, скомпилированных в рамках различных прагм, и мы рекомендуем, в общем, чтобы вы использовали эти прагмы вместо явного указания этих модификаторов. Для одной вещи, модификаторы затрагивают только шаблоны поиска и не распространяются даже на сделанную замену , тогда как использование прагма-директивы даёт постоянные результаты для всех соответствующие операций в пределах их области. Например,

s/foo/\Ubar/il

найдет "foo", используя локальные правила языкового стандарта для сопоставления без учета регистра, но /l не влияет, когда работает C <\U>. Скорее всего вы хотите, чтобы оба из них использовали локальные правила. Для этого нужно компилировать регулярное выражение в рамках use locale. Это неявно добавляет /l и применяет правила языка к C <\U>. Урок заключается в том, чтобы использовать use locale и не использоват явно /l.

Аналогичным образом было бы лучше использовать use feature 'unicode_strings' вместо

s/foo/\Lbar/iu

чтобы получить правила Юникода, как в бывшем \L (но не обязательно последнем) будет также использовать правила Юникода.

Более подробно о каждом из модификаторов смотри далее. Скорее всего вым не нужно знать эти детали для /l, /u и С</d> и можете пропустить вперед /a.

/l

используется для правил текущей локали (см. perllocale) когда шаблон найден. Например \w будет совпадать с символами "слова" текущей локали и "/i" регистронезависимый поиск будет искать согласно текущим правилам регистронезависимого сравнения. Будет использоваться одна локаль во время поиска по шаблону. Это может быть не то же самое, как во время локали времени компиляции и поиск может отличаться один от другого если еще есть промежуточный вызов из setlocale() function.

Perl поддерживает только однобайтовые локали. Это означает, что код символа, который выше 255, рассматриваются как Юникод независимо от того, какая локаль действует. Согласно правилам Юникода есть несколько локалей без учета регистра, которые пересекают границу 255/256 . Они запрещены при /l. Например, 0xFF (на ASCII платформах) не соответствует символу 0x178,LATIN CAPITAL LETTER Y WITH DIAERESIS, в подшаблоне , потому что 0xFF не может быть LATIN SMALL LETTER Y WITH DIAERESIS в текущей локали, и Perl не имеет возможности узнать даже существует ли этот символ в этой локали.

Этот модификатор можно определить, используя use locale, но посмотрите "Какой набор символьных модификаторов действует?".

/u

означает использования правил Unicode во время поиска по шаблону. На платформах ASCII это означает, что символы с кодом от 128 до 255 такие, как Latin-1 (ISO-8859-1) значения (которые такие же, как в Юникоде). (Иначе Perl считает, что их значение будет неопределенным). Таким образом, под этот модификатором платформа ASCII фактически становится Юникодной платформой; и следовательно, к примеру, \w будет соответствовать любому из более чем 100_000 буквенных символов в Юникоде.

В отличие от большинства локалей, которые являются специфическими для пары язык-страна, Юникод классифицирует все символы, как символ для письма, которые используются где угодно в мире, как \w. Например, ваша локаль может не считать LATIN SMALL LETTER ETH как строковый символ (пока вы не будете говорить на исландском), а Юникод принимает этот символ за строчный. Аналогичным образом все символы, десятичные цифры везде в мире будут соответствовать \d; это сотни, а не 10-ки возможных совпадений. И некоторые из этих цифр выглядят, как некоторые из 10 ASCII цифр, но означают другое число, поэтому человек легко может думать, что это совсем другое число, чем на самом деле. Например, BENGALI DIGIT FOUR (U+09EA) выглядит очень похоже на ASCII DIGIT EIGHT (U+0038). И \d+ может найти символы , которые могут соответствовать символам цифр, котрые представляют собой смесь из различных систем письма, созданных из соображений безопасности. "num()" in Unicode::UCD может использоваться для сортировки. А модификатор /a может использоваться для принудительного поиска шаблоном \d только ASCII цифр от 0 до 9.

Кроме того под этим модификатором, регистронезависимый поиск символов работает на полном наборе Юникодных символов. KELVIN SIGN, например совпадает с буквами "k" и "K"; и LATIN SMALL LIGATURE FF соответствует последовательности "ff", которая, если вы не подготовлены, может выглядеть, как шестнадцатеричная константа, что представляет еще одну потенциальную проблему безопасности. См. http://unicode.org/reports/tr36 для подробного обсуждения вопросов безопасности в Юникоде.

Этот модификатор может определяться по умолчанию, используя use feature 'unicode_strings, use locale ':not_characters', или use 5.012>> (или выше), но посмотрите главу "Какой набор символьных модификаторов действует?".

/d

Этот модификатор означает использование собственные правила платформы "По умолчанию", за исключением случаев, когда вместо этого есть основания для использования правил Юникода, следующим образом:

1. целевая строка кодируется в UTF-8; или

2. шаблон кодируется в UTF-8; или

3. шаблон явно упоминает код символа, который находится выше 255 (скажем \x{100}); или

4. шаблон использует Юникодное имя (\N{...}); или

5. шаблон использует Юникодное свойство (\p{...}); или

6. шаблон использует "(?[ ])"

Другая мнемоникак для этого модификатора "Зависит от", и правила, которые на самом деле используются зависят от различных вещей, и в результате вы можете получить неожиданные результаты. Смотрите "<Bug Юникода" in perlunicode. Ошибка Unicode становиться довольно печальной, ведущих к еще одному (версия для печати) имени для этого модификатора, "Dodgy" "Непредсказуемый" или "Рисковый".

Если шаблон или строки не кодируются в UTF-8, то буду найдены только символы ASCII.

Вот некоторые примеры того, как это работает на ASCII платформе:

$str =  "\xDF";      # $str не в UTF-8 формате.
$str =~ /^\w/;       # Не найдет, так как $str не в UTF-8 формате.
$str .= "\x{0e0b}";  # Теперь строка $str в UTF-8 формате.
$str =~ /^\w/;       # Найдет! $str теперь в UTF-8 формате.
chop $str;
$str =~ /^\w/;       # Все еще найдет! $str остается в UTF-8 формате.

Этот модификатор автоматически выбирается по умолчанию, если ни один другой не указан , таким образом для него другое имя — "По умолчанию" ("Default").

Из-за неожиданного поведения, связанные с этим модификатором, вам вероятно следует его использовать только, его вам нужно сохранить странные обратные совместимости.

/a (и /aa)

Этот модификатор выступает за ASCII строгость (или ASCII-безопасность). Этот модификатор, в отличие от других, может в два раза расширить свой эффект.

Когда он появляется один, то он применяется к последовательности \d, \s, \w, и классам символов Posix для соответствия только в диапазоне ASCII. Они, таким образом, возвращаются к версиям до 5.6 (pre-5.6), бывшим еще до значений Юникода (pre-Unicode). Под модификатором /a, \d всегда означает точко цифры от "0" до "9"; \s означает пять символов [ \f\n\r\t], и начиная с Perl v5.18, экспериментально, вертикальный табулятор; \w означает 63 символа [A-Za-z0-9_]; кроме того, все Posix классы такие как [[:print:]] найдут только соответствующие символы ASCII-диапазона.

Этот модификатор является полезным для людей, которые только изреда используют Юникод, и, которые не желают обременяться его сложностью и проблемами безопасности.

С модификатором /a, вы можете написать \d с уверенностью, что он точно найдет только ASCII символы, и, если вам нужно найти что-то за пределами сиволов ASCII, вы можете вместо этого использовать \p{Digit} (или \p{Word} для \w). Есть аналогичные конструкции \p{...} , которые могут соответствовать симолам за пределами ASCII как для пробельных символов (см. "Whitespace" in perlrecharclass) , так и для классов Posix (см. "POSIX Character Classes" in perlrecharclass. Таким образом этот модификатор не означает, что вы не можете использовать Unicode, это означает, что для поиска Юникодных символов вы должны явно использовать конструкцию (\p{}, \P{}), которая говорит о том, что это Юникод.

Как и следовало ожидать, этот модификатор вызывает, например, что \D означает то же, что и [^0-9]; в самом деле все не ASCII находят \D, \S, и \W. \b по-прежнему соответствует границе между \w и \W, используя свое определение при модификаторе /a (аналогично для \B).

В противном случае /a ведет себя как модификатор /u , в регистронезависимом поиске семантики Юникодных символов; к примеру будет "k" найдет юникодный \N{KELVIN SIGN} при поиске с модификатором /i и код символов в диапазоне Latin1, выше ASCII будет иметь правила Юникода, как они действуют при поиске без учета регистра.

Для запрещения поиска ASCII/не-ASCII (например, как "k" с \N{KELVIN SIGN}), поставьте "a" дважды, например /aai или /aia. (Первой появление "a" ограничивает \d, и так далее, а второе появление добавляет ограничение для /i.) Но, нужно заметить, что для символов вне диапазона ASCII будет использоваться правила Юникода для /i поиска, таким образом, модификатор, в действительности, не ограничивает символы только ASCII диапазоном; он просто запрещает смешение символов ASCII и не ASCII диапазона.

Подводя итог, этот модификатор обеспечивает защиту для приложений, которые не хотят быть подвержены влиянию Юникода. Указав его дважды вы получаете дополнительную защиту.

Этот модификатор может бытьуказан по-умолчанию с помощью use re '/a' или use re '/aa'. Если вы так сделаете, вы можете иметь возможность использовать модификатор /u явно, если существует несколько регулярных выражений, где вы хотите использовать полные правила Юникода (но даже здесь, лучше, если бы работала функция "unicode_strings", наряду с use re '/aa'). Также смотри "Какой набор символьных модификаторов действует?".

Какой набор символьных модификаторов действует?

Какой набор символьных модификаторов действует в любой месте регулярного выражения зависит от набора довольно сложных взаимодействий. Они разработаны таким образом, что в целом вам не придется беспокоиться об этом, но этот раздел даст вам кровавые подробности. Как объясняется ниже в "Расширенных шаблонах" это возможно явно указав модификаторы, которые применяются только к части регулярного выражения. Внутреннее всегда имеет приоритет над любым внешним и одно применение для целого выражения имеет приоритет над любым из параметров по умолчанию, описанному в оставшейся части этого раздела.

Прагма use re '/foo' может использоваться для установки модификаторов по умолчанию (включая эти) для скомпилированных регулярных выражений в пределах своей области. Эта прагма имеет приоритет над другими прагмами, перечисленные ниже, что также изменяет значения по умолчанию.

Иначе, use locale устанавливает модификатор по умолчанию в /l; и use feature 'unicode_strings, или use 5.012 (или выше) установка умолчания в /u когда не в той же области, либо как use locale или use bytes. (use locale ':not_characters' также устанавливают умолчание в /u, переопределяет и простой use locale.) В отличие от механизмов, упомянутых выше, эти операнды влияют на операции помимо поиска регулярного выражения по шаблону и поэтому дают более последовательные результаты с другими операторами, в том числе с использованием \U, \l и т.д. в операциях замены.

Если ни один из перечисленных выше вариантов не применяется, то, для обратной совместимости модификатор /d является в сущности по умолчанию. Так как это может привести к неожиданным результатам, то лучше указать какой другой набор правил должен использоваться.

Модификатор поведения набора символов до Perl 5.14

До 5.14, были не было явных модификаторов, но /l подразумевается для регулярных выражений, скомпилированные в соупе use locale и /d подразумевался иначе.Однако интерполяция регексов в больших регексах будет игнорировать оригинальную компиляцию в пользу всего, что было в действительности во время второй компиляции. Существует ряд несоответствий (ошибок) с модификатором /d , где правила Юникода будут неуместны и наоборот.C <\p{}> не подразумевает правил Юникода и не делает все вхождения \N{}, до 5.12.

Регулярные выражения

Метасимволы

Шаблоны, используемые в Perl эволюционировали от тех, которые были в Процедурах Регулярных Выражениях Версии 8 (Version 8 regex routines). Процедуры являются производными (отдаленно) от свободно распространяемой повторной реализации подпрограмм версии V8 Генри Спенсера . См. "Версия 8 Регулярных Выражений" для подробностей.

В частности следующие метасимволы имеют значения по egrep-ному стандарту:

\        Экранирование следующего метасимвола
^        Найдет начало строки
.        Найдет любой символ (кроме символа новой строки)
$        Найдет конец строки (перед символом новой строки в конце)
|        Альтернатива
()       Группировка
[]       Класс символов в квадратных скобках

По умолчанию, символ "^" гарантирует, что найдется только начало строки , а символ "$" найдет только конец (или перед символом новой строки в конце ), и Perl делает определенные оптимизации, предполагая, что набор символов содержит только одну строку. Внутренние новые строки не будут найдены "^" или "$". Вы можете, тем не менне пожелать представить символы для поиска как буфер из многих строк, тогда "^" будет найдет после любого символа новой строки внтури символов для поиска (исключанием является случай, когда символ новой строки является последним символом в строке поиска), и "$" найдет перед любым символом новой строки. Стоимость накладных расходов немного больше, если вы применяете к шаблону поиска модификатор /m. (Старые программы делали это, устанавливая $*, но эта возможность удалена в perl 5.10.)

Для упрощения замены в многострочном буфере, символ "." никогда не найдет символ новой строки, только, если вы не используете модификатор /s, который фактически сообщает Perl, что весь буфер для поиска - это одна строка --даже если это не так.

Повторители (Квантификаторы, умножители, символы, указывающие количество)

Существуют следующие стандартные повторители:

*           Найдет 0 или больше раз
+           Найдет 1 или больше раз
?           Найдет 1 или 0 раз
{n}         Найдет точно n раз
{n,}        Найдет по крайней мере n раз
{n,m}       Найдет по крайней мере n раз, но не более m раз

(Если фигурная скобка находится в любом другом контексте и не являются частью эскейп последовательности такой, как \x{...}, то она обрабатывается как обычный символ. В частности, нижняя граница повторителя не является обязательной, опечатка в повторителе молча рассматривает его, как буквенные символы. Например,

/o{4,3}/

выглядит как повторитель, который найдется 0 раз, так как 4 больше 3, но это в действительности это означает соответствие последовательности из шести символов "o { 4 , 3 }". Запланировано в конечном счете потребовать буквального использования из фигурных скобок, которых будут заэкранированы, скажите, поставив перед ними обратную косую черту или поставив их квадратные скобоки, , ("\{" или "[{]"). Это изменение будет допускать будущее расширения синтаксиса (как создание нижней границы повторителя, как опциональное), и лучшей проверки на ошибки. Тем временем вы должны привыкнуть избегать всех случаев, где вы имеете в виду чимвол "{".)

Повторитель "*" означает тоже, что и {0,}, повторитель "+" это {1,}, и "?" это {0,1}. n и m ограничены неотрицательными значениями меньше, чем заданный предел, определенный во время сборки perl. Это обычно 32766 на наиболее распространенных платформах. Фактический предел может будьте найден в сообщении об ошибке, произведенном следующим кодом:

$_ **= $_ , / {$_} / for 2 .. 42;

По умоланию повторительный подшаблон "жадный", это означает, что он будет искать максимальное число совпадений из возможного (наиная с указанной стартовой позиции) пока еще соответствие шаблону остается. Если вы хотите найти минимальное число совпадений , укажите после повторителя "?". Следует что значение шаблона не меняется, а только его "жадность":

*?        Найдёт 0 или больше раз, не жаден
+?        Найдёт 1 или больше раз, не жаден
??        Найдёт 0 или 1 раз, не жаден
{n}?      Найдёт точно n раз, не жаден (излишне)
{n,}?     Найдёт как минимум n раз, не жаден
{n,m}?    Найдёт как минимум n раз но не более m раз, не жаден

По умолчанию, когда повторенный вложенный шаблон не позволяет совпасть остальной части общего шаблона, Perl делает шаг назад (backtrack). Однако такое поведение является иногда нежелательно. Тогда Perl предоставляет форму "притяжательного" повторителя.

*+     Найдёт 0 или больше раз и не дает возврата
++     Найдёт 1 или больше раз и не дает возврата
?+     Найдёт 0 или 1 раз и не дает возврата
{n}+   Найдёт точно n раз и не дает возврата (излишне)
{n,}+  Найдёт как минимум n раз и не дает возврата
{n,m}+ Найдёт как минимум n раз но не более m раз и не дает возврата

Например,

'aaaa' =~ /a++a/

никогда не найдется, так как a++ будет съедать все a в строке и не оставит ни одного символа для оставшейся части шаблона. Эта особенность может быть экстремально полезна, давая перлу сигнал, где не должно быть возврата назад. Например, типичная проблема "поиска строки в двойных кавычках" может решиться наиболее эффективно, когда написано так:

/"(?:[^"\\]++|\\.)*+"/

как мы знаем, если последняя кавычка не находится, то поиск с возвратом не поможет.

Смотри независимое выражение "(?>pattern)" для деталей; притяжательные повторители являются только синтаксическим сахаром для этой конструкции. Например, пример, приведенный выше, может быть записан следующим образом:

/"(?>(?:(?>[^"\\]+)|\\.)*)"/

Эскейп последовательности (или последовательности обратной косой черты)

Поскольку шаблоны обрабатываются, как строки в двойных кавычках, то следующие последовательности также будут работать:

\t          табуляция                   (HT, TAB)
\n          новая строка               (LF, NL)
\r          ввод, перенос строки                (CR)
\f          Перевод формата (Formfeed)             (FF)
\a          Тревога (звуковой сигнал)          (BEL)
\e          Клавиша ESC (Escape) (think troff)  (ESC)
\cK         символ control          (пример: VT)
\x{}, \x00  порядковый номер символа, данный в шестнадцатиричном формате
\N{name}    Именованный символ Юникода или последовательность символов
\N{U+263D}  Юникодный символ     (пример: FIRST QUARTER MOON)
\o{}, \000  порядковый номер символа, данный в восьмеричном формате
\l          Следующий символ в нижнем регистре (думая vi)
\u          Следующий символ в верхнем регистре (думая vi)
\L          Нижний регистр до \E (думая vi)
\U          Верхний регистр до \E (думая vi)
\Q          (quote) Отключает действие метасиволов в шаблоне до \E
\E          Завершение модификации, конец случае модификации или заквотированной секции, думая vi

Подробнее смотри "Квотирование и Операторы заключения в кавычки" in perlop ("Quote and Quote-like Operators" in perlop).

Символьные типы и другие специальные эскейп символы

Кроме того Perl определяет следующее:

Последовательность   Замечание    Описание
 [...]     [1]  Найдет символ, который соответствует правилу в квадратных скобках,
                определенный "...".
                  Например: [a-z] найдет "a" или "b" или "c" ... или "z"
 [[:...:]] [2]  Найдет символ, который соответствует правилам POSIX
                   "..." класса символов в двойных квадратных скобках. Например: [[:upper:]] найдет любой 
                   символ в верхнем регистре.
 (?[...])  [8]  Расширенный класс символоd в скобках
 \w        [3]  Найдет символ "слова" (буквацифра плюс "_", плюс
                 другие соединительные знаки пунктуации, отметки Юникода)
 \W        [3]  Найдет символ не-"слова"
 \s        [3]  Найдет пробельный символ
 \S        [3]  Найдет не пробельный символ
 \d        [3]  Найдет символ десятичной цифры
 \D        [3]  Найдет отрицание символа десятичной цифры
 \pP       [3]  Найдет P, именованное свойство. Ипользуйте \p{Prop} для длинных имен
 \PP       [3]  Найдет не-P
 \X        [4]  Найдет Юникодный "расширенный графема кластер"
 \C             Найдет один символ из языка C (октет - 8 битб 1 байт) даже, если он часть
                  большого UTF-8 символа.  Таким образом он ломает символы в их байты из UTF-8, так что вы можете 
                  получить искаженные кусочки(malformed pieces) UTF-8.
                  Не поддерживается в поиске вперед.
 \1        [5]  Обратная ссылка на конкретную группу или буфер.
                  '1' на самом деле может быть любое положительное целое число.
 \g1       [5]  Обратная ссылка на конкретную или предыдущую группу,
 \g{-1}    [5]  Числа могут быть отрицательными, указывать относительно
                 предыдущей группы и при необходимости могут быть обернуты в
                 фигурные скобки для безопасного синтаксического разбора.
 \g{name}  [5]  Именованная обратная ссылка
 \k<name>  [5]  Именованная обратная ссылка
 \K        [6]  Сохраняет найденный материал слева от \K, не включая его в $&
 \N        [7]  Любой символ, кроме \n.  Не влияет на модификатор /s
 \v        [3]  Вертикальный пробел
 \V        [3]  Невертикальный пробел
 \h        [3]  Горизонтальный пробел
 \H        [3]  Негоризонтальный пробел
 \R        [4]  Универсальная новая строка

[1]

См. "Bracketed Character Classes" in perlrecharclass для деталей.

[2]

См. "POSIX Character Classes" in perlrecharclass для деталей.

[3]

См. "Backslash sequences" in perlrecharclass для деталей.

[4]

См. "Misc" in perlrebackslash для деталей.

[5]

См. "Группы захвата" ниже для деталей.

[6]

См. "Расширенные шаблоны поиска" ниже для деталей.

[7]

Обратите внимание, что \N имеет два значения. Когда он в форме \N{NAME}, он соответствует символу или последовательности символов, которые называются NAME; и так же, когда форма \N{U+hex}, она соответствует символу Юникода, в шестнадцатиричном коде — <hex>. В противном случае он соответствует любому символу, кроме \n.

[8]

See "Расширенная классы скобочных символов (Extended Bracketed Character Classes)" in perlrecharclass для деталей.

Утверждения

Perl определяет следующие утверждения нулевой длины:

\b  Найдет границу слова
\B  Найдет все, кроме границы слова
\A  Найдет начало строки
\Z  Найдет только в конце строки или перед новой строкой в конце
\z  Найдет только в конце строки
\G  Найдет только в pos() (т.е. в конце последней найденной позиции m//g)

Граница слова (\b) это место между двумя символами, которые содержат \w на одной их стороне и \W на другой (в любом порядке), считая воображаемые символы начала и конца строки, как \W. (Внутри сивольных классов \b представляет клавишу backspace, а не границу слова,так, как это обычно бывает в любой строке в двойных кавычках.) \A и \Z работают также, как и "^" и "$", за исключением того, что они не будут искать несколько раз, когда используется модификатор /m , тогда как "^" и "$" будут соответствовать каждой внутренней линии границы. Чтобы найти актуальный конец строки и не игнорировать дополнительные конечные строки, используйте \z.

Утверждение \G можно использовать для глобального поиска (используя m//g), как описано в "Квотирование и Операторы заключения в кавычки" in perlop ("Quote and Quote-like Operators" in perlop). Это также удобно во время написания lex-подобных сканнеров, когда у вас есть несколько паттернов, которым вы хотите сопоставить последующие подстроки строки; cмотрите предыдущие ссылки. Фактическое местонахождение, где \G будет находить, также может определяться с помощью pos() как lvalue(левое значение): см. "pos" in perlfunc. Обратите внимание, что правило нулевой длины (см. "Повторяющиеся шаблоны, находящие подстроки нулевой длины" ("Repeated Patterns Matching a Zero-length Substring")) изменяется несколько в том, что содержимое слева от \G не учитываются при определении длины найденного. Таким образом следующее никогда не будет соответствовать:

my $string = 'ABC';
pos($string) = 1;
while ($string =~ /(.\G)/g) {
    print $1;
}

Он напечатет 'A' и остановиться, т.к. будет считаться, что был поиск нулевой ширины и таким образом - он не будет соответствовать одной и той же позиции дважды в строке.

Стоит отметить, что \G при не правильном использовании может привести к бесконечному циклу. Будьте осторожны при использовании шаблонов, которые включают \G как альтернативу.

Группы захвата

Скобочная конструкция ( ... ) создаёт группы захвата (также именуется как буферы захвата). Чтобы сослаться на текущее содержимое группы позже в пределах текущего шаблона поиска нужно использовать \g1 (или \g{1}) для первой, \g2 (или \g{2}) для второй группы и так далее. Это называется обратной ссылкой (backreference).

Количество захваченных подстрок, которые вы можете использовать не ограничено. Группы нумеруются с левой открывающей круглой скобки номер 1, и т.д. Если группа не найдена, связанные обратные ссылки тоже не будут совпадать. (Это может случиться, если группа не является обязательной, или поиск идет в альтернативной ветке). Вы можете опустить "g" и написать "\1", и т.д., но с этим есть некоторые проблемы, описанные ниже.

Также можно захватывать группы относительно друг друга, используя отрицательное число, так С<\g-1> и С<\g{-1}> оба относятся к группе непосредственно перед захватом и \g-2 и \g{-2} относятся к группе перед ней. Например:

/
 (Y)            # группа 1
 (              # группа 2
    (X)         # группа 3
    \g{-1}      # обратная ссылка на группу 3
    \g{-3}      # обратная ссылка на группу 1
 )
/x

поиск будет таким же, как /(Y) ( (X) \g3 \g1 )/x. Это позволяет интерполировать регулярные выражения в большие регулярные выражения и тогда не придется беспокоиться о перенумерации групп захвата.

Можно вообще обойтись числами и создать именованные группы захвата. Нужно объявить (?<name>...) и \g{name} для такой ссылки. (Чтобы быть совместимым с регулярные выражения .Net, \g{name} также может быть написано как \k{name}, \k<name> или \k'name'.) name не должно начинаться с цифры или содержать дефисы. Если несколько групп в рамках шаблона имеют одинаковое имя, то любая ссылка на это имя подразумевает самую левую определяемую группу. Именованные группы уичтываются и в абсолютной и в относительной нумерации и на них также можно сослаться с помощью номера.

(Это делает возможным делать вещи с именованными группами захвата, которые бы в противном случае требовали бы (??{}).)

Cодержимое захваченной группы определяется динамически и оно доступно для вас вне шаблона поиска до конца закрывающего блока или до следующего успешного поиска, что наступит раньше. (См. "Составные операторы" in perlsyn.) Вы можете обращаться к ним по абсолютному номеру (используя "$1" вместо "\g1", и т.д.); или по имени через хэш %+, с помощью "$+{name}".

Скобки требуются для ссылки на именованные группы захвата, но являются опциональными для абсолютной или относительной нумерации групп. Скобки являются более безопасными, когда созданется регулярное выражение объединение меньших строк. Например, если у вас есть qr/$a$b/ и $a содержит "\g1", и $b содержит "37", вы получите /\g137/, что является, вероятно, не тем, что вы хотели.

Обозначения \g и\k были введены в Perl 5.10.0. До этого не было ни именованных, ни относительно пронумерованных групп захвата. Абсолютная нумерация группы передавалась с помощью \1, \2 и т.д., и эта запись до сих пор принимается (и скорее всего всегда будет). Но это приводит к некоторым неясностям, если есть более чем 9 групп захвата, так \10 может означать либо десятую группу захвата, или символ, чей порядковый номер восьмеричное-010 (бэкспейс (пробел назад) в ASCII). Perl разрешает эту неопределенность путем интерпретации \10 как обратной ссылки только, если по крайней мере 10 левых скобок были открыты перед ней. Аналогичным образом, \11 - это обратная ссылка только, если по крайней мере 11 левых скобок открыты перед ней. И так далее. От \1 до \9 всегда интерпретируются как обратные ссылки. Есть несколько примеров ниже, которые иллюстрируют эти риски. Вы можете избежать двусмысленности всегда используя \g{} или \g, если вы имеете в виду захватываемые группы; и для восьмеричных констант всегда использовать \o{}, или для \077 и ниже, используя 3 цифры с ведущими нулями, поскольку лидирующий ноль означает восьмеричную константу.

Обозначения \digit также работает в определенных обстоятельствах за пределами шаблона. Смотри "Предупреждение на \1 вместо $1" ниже для деталей.

Examples:

s/^([^ ]*) *([^ ]*)/$2 $1/;     # поменять местами первые два слова

/(.)\g1/                        # найдет первый дублирующий символ
     and print "'$1' is the first doubled character\n";

/(?<char>.)\k<char>/            # ... другой способ
     and print "'$+{char}' is the first doubled character\n";

/(?'char'.)\g1/                 # ... смешанный поиск
     and print "'$1' is the first doubled character\n";

if (/Time: (..):(..):(..)/) {   # разобрать значения
    $hours = $1;
    $minutes = $2;
    $seconds = $3;
}

/(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 - это обратная ссылка
/(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 - восьмеричное число
/((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 - это обратная ссылка
/((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 - восьмеричное число

$a = '(.)\1';        # Создает проблемы, когда объединяются.
$b = '(.)\g{1}';     # Позволяет избежать проблем.
"aa" =~ /${a}/;      # Правда
"aa" =~ /${b}/;      # Правда
"aa0" =~ /${a}0/;    # Ложь!
"aa0" =~ /${b}0/;    # Правда
"aa\x08" =~ /${a}0/;  # Правда!
"aa\x08" =~ /${b}0/;  # Ложь

Несколько специальных переменных также вернут порцию предыдущего поиска. $+ вернет результат найденного в последней скобке. $& вернет всю совпадающую строку. (Раньше это делал $0, но теперь он возвращает имя программы.) $` вернет все перед совпавшей строкой.$' вернет все после совпавшей строки. И $^N содержит все, что было найдено в самой недавно закрытой группе (подстроку). $^N может быть использован в расширенные шаблонах (см. ниже), например назначить найденную подстроку переменной.

Существуют специальные переменные такие как хеш %+ и пронумерованные переменные поиска ($1, $2, $3, и т.д.) динамически распространяющиеся до конца закрывающего блока или до следующего успешного поиска, что наступит раньше. (См. "Составные операторы" in perlsyn.) (См. "Compound Statements" in perlsyn.)

ЗАМЕЧАНИЕ: неудачные поиски в Perl не сбрасывают переменные поиска, что упрощает написание кода, который проверяет серию конкретных случаев и запоминает лучший поиск.

ПРЕДУПРЕЖДЕНИЕ: как только Perl видит, что вам нужна одна из переменных $&, $`, или $' где-либо в программе, он должен предоставить их для каждого поиска по шаблону. Это может существенно замедлить вашу программу. Perl использует тот же механизм для производства $1, $2, и т.д., так, что вы также платите существенную цену для каждого шаблона, который содержит захватывающие скобки. (Чтобы избежать этой платы при сохранении группирующего поведения, используйте вместо этого расширенное регулярное выражение (?: ... ) .) Но если вы никогда не используете $&, $` или $', тогда шаблоны без захватывающих скобок не будут наказаны. Поэтому избегайте$&, $', или $`, если можете, но если вы не можете (и я очень ценю некоторые такие алгоритмы), после того как вы использовали их один раз, использовать их по своему желанию, потому что вы уже за низ заплатили. По состоянию на 5.17.4, присутствие каждой из трех переменных в программе регистрируется отдельно и, в зависимости от обстоятельства, perl может быть в состоянии быть более эффективным зная что только $& , а не все три будут использованы, например.

Для того, чтобы обойти эту проблему Perl 5.10.0 представляет переменные ${^PREMATCH}, ${^MATCH} и${^POSTMATCH}, которые эквивалентны $`, $& и $', исключая то, что только они будут гарантированно определены после успешного поиска, который был выполнен с модификатором /p (preserve) (сохранять) . Использование этих переменных не влечет к штрафу глобальной производительности, в отличие от их эквивалента в виде знаков препинания, однако здесь вы идете на компромисс того, что вы должны сказать perl, когда вы хотите их использовать. X <p модификатор>

Квотирующие метасимволы (Quoting metacharacters)

Метасимволы с обратным слэшем в Perl являются буквенно-цифровыми, например \b, \w, \n. В отличие от некоторых других языков с регулярными выражениями, не существует символов с обратным слэшем, которые не являются буквенно-цифровыми. Так что все, что выглядит как \\, \(, \), \ [, \], \ {, или \} всегда интерпретируется как буквенный символ, а не метасимвол. Это было некогда общей идеей для отключения или квотирования (оборачивание в кавычки) метасимволов, имеющих специальное значение в регулярных выражениях, которых вы хотите использовать для шаблоне поиска. Теперь заквотируем (поставим обратный слэш) для всех не-"словесных" символов:

$pattern =~ s/(\W)/\\$1/g;

(Если установлено use locale, то это зависит от текущей локали.) Сегодня чаще используют функцию quotemeta() или С<\Q> метаквотированный эскейп символ для отключения специальных значений всех метасимволов следующим образом:

/$unquoted\Q$quoted\E$unquoted/

Учтите, что если вы положите символ косой черты (который не внутри переменных с интерполяцией) между \Q и \E, двойное квотирование интерполяции обратной косой черты может привести к нежелательным результатам. Если вам нужно использовать символ косой черты в пределах \Q...\E, проконсультируйтесь с ("Кровавые подробности разбора закавыченных(квотированных) конструкций" in perlop) ("Gory details of parsing quoted constructs" in perlop).

quotemeta() и \Q полностью описаны в "quotemeta" in perlfunc.

Расширенные шаблоны

Perl также определяет синтаксис последовательного расширения функций не входящих в стандартные инструменты, такие как awk и lex. Синтаксис для большинства из них - это пара скобок с вопросительным знаком идущим сразу за первой скобкой. Символ идущий за вопросительным знаком указывает расширение.

Стабильность этих расширений колеблется в широких пределах. Некоторые из них были частью основного языка на протяжении многих лет. Другие экспериментальные и могут меняться без предупреждения или быть полностью удалены. Проверяйте документацию для каждого компонента для проверки его текущего статуса.

Вопросительный знак был выбран для этого и для минимального соответствия конструкции потому что 1) вопросительные знаки встречаются редко в старых регулярных выражения и 2) всякий раз, когда вы его видите, вы должны остановиться и "задаться вопросом" точности того, что происходит. Это психология...

(?#text)

Комментарий. Текст игнорируется. Если модификатор /x позволяет использование пробельных символов для форматирования, то простого # будет достаточно. Обратите внимание, что Perl закрывает комментарий, как только он видит ), так что нет никакого способа положить литерал (символ) ) в комментарий.

(?adlupimsx-imsx)

(?^alupimsx)

Один или несколько встроенных модификаторов в шаблон, чтобы быть включенным (или выключенным, если предшествует -) на оставшуюся часть шаблона или оставшуюся часть закрытой группы поиска(если таковые имеются).

Это особенно полезно для динамических шаблонов, например, которые читаются из файла конфигурации, взяты из аргумента, или указаны в таблице где-либо. Рассмотрим случай, когда некоторые шаблоны хотят быть с учетом регистра,а другие нет: для того, чтобы поиска части шаблона был без учета регистра, то необходимо включить (?i) перед шаблоном. Например:

$pattern = "foobar";
if ( /$pattern/i ) { }

# более гибко:

$pattern = "(?i)foobar";
if ( /$pattern/ ) { }

These modifiers are restored at the end of the enclosing group. For example, Эти модификаторы восстанавливаются в конце внешней группы. Например,

( (?i) blah ) \s+ \g1

который найдет blah в любом регистре, некоторые пробелы и точное (включая регистр!) повторение предыдущего слова, предполагая модификатор /x, а теперь нет модификатора /i за пределами этой группы.

Эти модификаторы не переносятся в именованные подмаски, вызванные в закрытой группе. Другими словами шаблон например ((?i)(?&NAME)) не измененяет чувствительности регистра для шаблона «"NAME".

Любой из этих модификаторов можно установить, что применить его глобально для всех регулярных выражений, скомпилированные в сфере use re. См. "'/flags' mode" in re.

Начиная с Perl 5.14, "^" (курсор или диакритический акцент) сразу за "?" это сокращение соответствует d-imsx. Флаги (кроме "d") можгут следовать после курсора для переопределения. Но минус не является легальным с ним.

Учтите, что модификаторы a, d, l, p, и u являются специальными здесь они могут быть включены, не не выключены, а модификаторы a, d, l, и u являются взаимоисключающими: указав один вы отрицаете другой, и максимум один из них (или два a) может появится в этой конструкции. Таким образом, (?-p) предупредит при компиляции при use warnings; (?-d:...) и (?dl:...) дадут фатальную ошибку.

Также, обратите внимание, что модификатор p имеет особое значение в том, что его присутствие в люом месте в шаблоне имеет глобальный эффект.

(?:pattern)

(?adluimsx-imsx:pattern)

(?^aluimsx:pattern)

Это для кластеризации, но не для захвата; он группирует подвыражения как "()", но не делает обратной ссылки, как это делает "()". Так что

@fields = split(/\b(?:a|b|c)\b/)

подобно

@fields = split(/\b(a|b|c)\b/)

но не выплевывает дополнительные поля. Также дешевле не захватывать группы , если вам не нужно.

Любые символы между ? и : действуют как флаги модификаторов, такие как (?adluimsx-imsx). Например,

/(?s-i:more.*than).*million/i

эквивалентно более подробному

/(?:(?s-i)more.*than).*million/i

Начиная с Perl 5.14, "^" (курсор или диакритический акцент) сразу за "?" это сокращение соответствует d-imsx. Любые позитивные флаги (кроме "d") можгут следовать после курсора, таким образом

(?^x:foo)

эквивалентно

(?x-ims:foo)

Курсор рассказывает Perl, что этот кластер не наследует флаги любых окружающих шаблонов, но использует системные умолчания (d-imsx), измененные любыми указанными флагами.

Курсор позволяет упростить создание строчек (stringification) из скомпилированных регулярных выражений. Они выглядят как

(?^:pattern)

с любыми флагами не по умолчанию, появляющимися между курсором и двоеточием. Тест, который выглядит, как перевод в строку (stringification), таким образом, не нуждается в в флагах по умолчанию, жестко зашитых в нем, только курсор. Если новые флаги будут добавлены в Perl, смысл курсора расширения изменится включением флагов по умолчанию, поэтому тест все еще будет работать, без изменений.

Указание отрицательных флага, после курсора ^, является ошибкой, т.к. как флаг является излишним.

Мнемоника для (?^...): свежее начало, поскольку галка обычно используется для поиска начала.

(?|pattern)

Это "сброс ветки" шаблона, который имеет специальные свойства, когда захватываемые группы нумеруются с той же начальной точки в каждой чередующейся ветке . Он доступен начиная с perl 5.10.0.

Группы захвата нумеруются слева направо, но внутри этой конструкции нумерация возобновляется для каждой ветви.

Нумерация в пределах каждой ветки будет нормальной и все группы следующие за этой конструкцией будут пронумерованы так,как-будто бы конструкция содержится только одну ветвь, ту, которая попадет в группу захвата.

Эта конструкция является полезной, когда вы хотите захватить одну из нескольких альтернативных групп.

Рассмотрим следующий шаблон. Цифры над под выражением показывают номера групп захвата.

# before  ---------------branch-reset----------- after        
/ ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
# 1            2         2  3        2     3     4  

Будьте внимательны при использовании сброса ветки шаблона в сочетании с именем захвата. Именованные захваты реализованы как псевдонимы нумерованным группам, что мешает осуществлению сброса ветки шаблона. Если вы используете именованный захват в сбросе ветки шаблона, то лучше использовать те же имена, в том же порядке, в каждом из альтернатив:

/(?|  (?<a> x ) (?<b> y )
   |  (?<a> z ) (?<b> w )) /x

Не делайте так, это может привести к сюрпризам:

"12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
say $+ {a};   # Prints '12'
say $+ {b};   # *Also* prints '12'.

Проблема здесь в том, что обе группы назвали a, а группа с именем b является алиасом для группы, принадлежащей к $1.

Утверждения Осмотра Вокруг (Look-Around Assertions)

Утверждения Осмотра Вокруг представляют собой шаблоны нулевой ширины, которые находя специфические элементы без включения результата в $&. Позитивные утверждения находяться, когда подмаски находятся, отрицательные утверждения находятся, когда поиск по подмаске не удачный. Осмотр-До(look-behind) находит текст до текущей позиции, Осмотр-После(look-ahead) находит текст следующий за позицией поиска.

(?=pattern)

Позитивное нулевой ширины утверждение поиска вперед. Например, /\w+(?=\t)/ найдет слово, за которым следует табуляция без ключения таба в $&.

(?!pattern)

Негативное нулевой ширины утверждение поиска вперед. Наприметр /foo(?!bar)/ найдет любое вхождение "foo" за которым не следует "bar". Замечание. Однако поиск вперед и назад не то же самое. Вы не можете использовать это для поиска назад.

Если вы ищете "bar" перед которым нет "foo", /(?!foo)bar/ , то будет искаться не то, что вы хотите. Потому что (?!foo) означает, что следующая вещь не может быть "foo"--но это не так, это "bar", таким образом "foobar" будет найден. Используйте вместо этого поиск назад (смотрите ниже).

(?<=pattern) \K

Позитивное нулевой ширины утверждение поиска назад. Например, /(?<=\t)\w+/ найдет слово, перед которым стоит таб, без включения таба в $&. Работает только для поиска назад фиксированной длины.

Существует специальная форма этой конструкции, называемая \K, которая влияет на регекс движок таким образом, что он "сохраняет" все, что было найдено перед \K и не включает это в $&. Это обеспечивает эффективный поиск назад переменной длины. Использования \K внутри другого утверждения Осмотра Вокруг возможно, но это поведение еще хорошо не определено.

Для различных причин \K может быть значительно более эффективным, чем эквивалентная конструкция (?<=...) и он особенно полезен в ситуации, где вы хотите эффективно удалить что-то следующее после строки. К примеру

s/(foo)bar/$1/g;

можно переписать гораздо более эффективно

s/foo\Kbar//g;

(?<!pattern)

Отрицающее утверждение нулевой ширины поиска назад. Например /(?<!bar)foo/ найдет вхождения "foo" , которые не следуют за "bar". Работает только для поиска назад фиксированной длины.

(?'NAME'pattern)

(?<NAME>pattern)

Имя захваченной группы. Идентично во всех отношениях для нормального захвата скобками (), но есть для дополнительной факт то, что к группе можно обращаться по имени в различных конструкциях регулярных выражений (например, \g{NAME}) и может быть доступен по имени после успешного поиска через %+ или %-. См. perlvar для более подробной информации о хэшах %+ и %-.

Если несколько различных захватываемых групп имеют одинаковые имена, то $+{NAME} будет ссылаться на самую левую и этих групп.

Формы (?'NAME'pattern) и (?<NAME>pattern) эквивалентны.

ПРИМЕЧАНИЕ: Хотя нотация этой конструкции такая же, как в регексах .NET , но поведение не совпадает. В Perl являются группы нумеруются последовательно, независимо от того именованные они или нет. Таким образом, в шаблоне

/(x)(?<foo>y)(z)/

$+{foo} будет тоже, что и $2, и $3 будет содержать 'z' вместо того, что хакер .NET регекса мог бы ожидать.

В настоящее время имя ограничивается простым идентификатором. Другими словами, он должен совпадать с /^[_A-Za-z][_A-Za-z0-9]*\z/ или его Юникодным расширением (см. utf8) хотя он не поддерживает докали (locale) (см. perllocale).

ПРИМЕЧАНИЕ: для того, чтобы сделать вещи проще для программистов с опытом работы с Python или движком регексов PCRE, шаблон (?P<NAME>pattern) может быть использован вместо (?<NAME>pattern); Однако эта форма не поддерживает использование одинарных кавычек в качестве разделителя для имени.

\k<NAME>

\k'NAME'

Именованная обратная ссылка. Похожа на цифровую обратную ссылку за исключением случаев , когда группа обозначается именем, а не числом. Если несколько групп имеют то же имя, то оно относится к самой левой найденной группе в текущем поиске.

Будет сообщение об ошибке, если будет ссылка на имя не определенное C << (? <NAME>) >> ранее в шаблоне.

Обе формы являются эквивалентными.

ПРИМЕЧАНИЕ: для того, чтобы сделать вещи проще для программистов с опытом работы с Python или движком регексов PCRE, шаблон (?P=NAME) может быть использован вместо \k<NAME>.

(?{ code })

ПРЕДУПРЕЖДЕНИЕ: Эта функция расширенных регулярных выражений считается экспериментальной и может быть изменена без предварительного уведомления. Выполняемый код имеет побочные эффекты, которые могут быть не одинаковыми от версии к версии из-за эффекта будущего оптимизаций в движке регексов (regex engine). Для осуществление этой функции был радикально пересмотрен 5.18.0 релиз и его поведение в более ранних версиях perl было намного более бажное (с большим числом багов), особенно в отношении разбора, лексических переменных, их действия, рекурсии и повторного входа (to parsing, lexical vars, scoping, recursion and reentrancy).

Это утверждение нулевой ширины выполняет любой встроенный код Perl. Оно всегда завершается успешно, и ее возвращаемое значение устанавливается как $^R.

В буквенных шаблонах, код парсится в то же время, как окружающий код. Во время обработки шаблона управление временно передаётся анализатору perl пока не находистся закрывающая скобка. Это похоже путь, которым индекс массива вытаскивает строку, например

"abc$array[ 1 + f('[') + g()]def"

В частности, скобки не обязательно должны быть сбалансированы:

s/abc(?{ f('{'); })/def/

Даже, если шаблон является интерполяцией и компилируется во время выполнения, литеральные блоки кода компилируются один раз, во время компиляции perl; следующее печатает "ABCD":

print "D";
my $qr = qr/(?{ BEGIN { print "A" } })/;
my $foo = "foo";
/$foo$qr(?{ BEGIN { print "B" } })/;
BEGIN { print "C" }

В шаблонах, где текст кода является производным от информации времени выполнения , а не появляется буквально в исходный коде /шаблоне/, код компилируется в то же время, что и шаблон, и, по соображениям безопасности, use re 'eval' должен быть в области. Это нужно для остановки пользовательских шаблонов, содержащие фрагменты кода, которые будут выполнены.

В ситуациях, когда вам нужно включить это с use re 'eval' вы должны также включить проверку на чужеродные примеси в коде( taint ) Еще лучше, используйте аккуратно ограничения выполнения в рамках безопасного отсека (Safe compartment.). Смотрите perlsec для деталей работы обоих этих механизмов.

С точки зрения анализа, лексическая область видимости переменной и замыканий (closures),

/AAA(?{ BBB })CCC/

ведет себя примерно как

/AAA/ && do { BBB } && /CCC/

Аналогичным образом,

qr/AAA(?{ BBB })CCC/

ведет себя примерно как

sub { /AAA/ && do { BBB } && /CCC/ }

В частности:

{ my $i = 1; $r = qr/(?{ print $i })/ }
my $i = 2;
/$r/; # prints "1"

Внутри блока (?{...}), $_ относится к строке регулярного выражения стоящего напротив. Вы также можете использовать pos(), чтобу узнать текущую позицию соответствия внутри этой строки.

Блок кода вводит новую область с точки зрения лексического объявления переменных, но не с точки зрения логального и аналогичного локализованного поведения. Чуть позже блоки кода в том же шаблоне будет по-прежнему видеть значения, которые были локализованы в предыдущих блоках. Эти накопленные локализации отменяются либо в конце успешного поиска, или, если утверждение возвратилось (assertion is backtracked) (сравните "Backtracking"). Например,

$_ = 'a' x 8;
m<
   (?{ $cnt = 0 })               # Инициализация $cnt.
   (
     a
     (?{
         local $cnt = $cnt + 1;  # Обновляем $cnt,
                                 # обратная ссылка безопасна (backtracking-safe).
     })
   )*
   aaaa
   (?{ $res = $cnt })            # При удачном поиске копирование в
                                 # не-локализованную локацию.
 >x;

первоначально увеличит $cnt до 8; затем во время отступает, его значение будет развернуто обратно до 4, это значение назначается C <$res>. В конце выполнения регекса $cnt будет уменьшено обратно в свое первоначальное значение 0.

Это утверждение может использоваться как условие в

(?(condition)yes-pattern|no-pattern)

свиче (переключателе). Если не использовать таким образом, то результат выполнения кода помещается в специальную переменную $^R. Это происходит сразу же, так только $^R может быть использован с другими (?{ code }) утверждениями внутри того же самого регулярного выражения.

Присваивание С<$^R> выше правильно локализовано, так, что старое значение $^R восстанавливается, если утверждение возвратилось при поиске; сравните L <"Поиск с возвратом">.

Обратите внимание, что специальная переменная $^N особенно полезна с блоками кода для записи результатов подсовпадений в переменных без необходимости отслеживать количество вложенных скобок. Например:

$_ = "The brown fox jumps over the lazy dog";
/the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
print "color = $color, animal = $animal\n";

(??{ code })

WARNING: This extended regular expression feature is considered experimental, and may be changed without notice. Code executed that has side effects may not perform identically from version to version due to the effect of future optimisations in the regex engine.

This is a "postponed" regular subexpression. It behaves in exactly the same way as a (?{ code }) code block as described above, except that its return value, rather than being assigned to $^R, is treated as a pattern, compiled if it's a string (or used as-is if its a qr// object), then matched as if it were inserted instead of this construct.

During the matching of this sub-pattern, it has its own set of captures which are valid during the sub-match, but are discarded once control returns to the main pattern. For example, the following matches, with the inner pattern capturing "B" and matching "BB", while the outer pattern captures "A";

my $inner = '(.)\1';
"ABBA" =~ /^(.)(??{ $inner })\1/;
print $1; # prints "A";

Note that this means that there is no way for the inner pattern to refer to a capture group defined outside. (The code block itself can use $1, etc., to refer to the enclosing pattern's capture groups.) Thus, although

('a' x 100)=~/(??{'(.)' x 100})/

will match, it will not set $1 on exit.

The following pattern matches a parenthesized group:

$re = qr{
           \(
           (?:
              (?> [^()]+ )  # Non-parens without backtracking
            |
              (??{ $re })   # Group with matching parens
           )*
           \)
        }x;

See also (?PARNO) for a different, more efficient way to accomplish the same task.

Executing a postponed regular expression 50 times without consuming any input string will result in a fatal error. The maximum depth is compiled into perl, so changing it requires a custom build.

(?PARNO) (?-PARNO) (?+PARNO) (?R) (?0)

Similar to (??{ code }) except that it does not involve executing any code or potentially compiling a returned pattern string; instead it treats the part of the current pattern contained within a specified capture group as an independent pattern that must match at the current position. Capture groups contained by the pattern will have the value as determined by the outermost recursion.

PARNO is a sequence of digits (not starting with 0) whose value reflects the paren-number of the capture group to recurse to. (?R) recurses to the beginning of the whole pattern. (?0) is an alternate syntax for (?R). If PARNO is preceded by a plus or minus sign then it is assumed to be relative, with negative numbers indicating preceding capture groups and positive ones following. Thus (?-1) refers to the most recently declared group, and (?+1) indicates the next group to be declared. Note that the counting for relative recursion differs from that of relative backreferences, in that with recursion unclosed groups are included.

The following pattern matches a function foo() which may contain balanced parentheses as the argument.

$re = qr{ (                   # paren group 1 (full function)
            foo
            (                 # paren group 2 (parens)
              \(
                (             # paren group 3 (contents of parens)
                (?:
                 (?> [^()]+ ) # Non-parens without backtracking
                |
                 (?2)         # Recurse to start of paren group 2
                )*
                )
              \)
            )
          )
        }x;

If the pattern was used as follows

'foo(bar(baz)+baz(bop))'=~/$re/
    and print "\$1 = $1\n",
              "\$2 = $2\n",
              "\$3 = $3\n";

the output produced should be the following:

$1 = foo(bar(baz)+baz(bop))
$2 = (bar(baz)+baz(bop))
$3 = bar(baz)+baz(bop)

If there is no corresponding capture group defined, then it is a fatal error. Recursing deeper than 50 times without consuming any input string will also result in a fatal error. The maximum depth is compiled into perl, so changing it requires a custom build.

The following shows how using negative indexing can make it easier to embed recursive patterns inside of a qr// construct for later use:

my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
if (/foo $parens \s+ \+ \s+ bar $parens/x) {
   # do something here...
}

Note that this pattern does not behave the same way as the equivalent PCRE or Python construct of the same form. In Perl you can backtrack into a recursed group, in PCRE and Python the recursed into group is treated as atomic. Also, modifiers are resolved at compile time, so constructs like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will be processed.

(?&NAME)

Recurse to a named subpattern. Identical to (?PARNO) except that the parenthesis to recurse to is determined by name. If multiple parentheses have the same name, then it recurses to the leftmost.

It is an error to refer to a name that is not declared somewhere in the pattern.

NOTE: In order to make things easier for programmers with experience with the Python or PCRE regex engines the pattern (?P>NAME) may be used instead of (?&NAME).

(?(condition)yes-pattern|no-pattern)

(?(condition)yes-pattern)

Conditional expression. Matches yes-pattern if condition yields a true value, matches no-pattern otherwise. A missing pattern always matches.

(condition) should be one of: 1) an integer in parentheses (which is valid if the corresponding pair of parentheses matched); 2) a look-ahead/look-behind/evaluate zero-width assertion; 3) a name in angle brackets or single quotes (which is valid if a group with the given name matched); or 4) the special symbol (R) (true when evaluated inside of recursion or eval). Additionally the R may be followed by a number, (which will be true when evaluated when recursing inside of the appropriate group), or by &NAME, in which case it will be true only when evaluated during recursion in the named group.

Here's a summary of the possible predicates:

(1) (2) ...

Checks if the numbered capturing group has matched something.

(<NAME>) ('NAME')

Checks if a group with the given name has matched something.

(?=...) (?!...) (?<=...) (?<!...)

Checks whether the pattern matches (or does not match, for the '!' variants).

(?{ CODE })

Treats the return value of the code block as the condition.

(R)

Checks if the expression has been evaluated inside of recursion.

(R1) (R2) ...

Checks if the expression has been evaluated while executing directly inside of the n-th capture group. This check is the regex equivalent of

if ((caller(0))[3] eq 'subname') { ... }

In other words, it does not check the full recursion stack.

(R&NAME)

Similar to (R1), this predicate checks to see if we're executing directly inside of the leftmost group with a given name (this is the same logic used by (?&NAME) to disambiguate). It does not check the full stack, but only the name of the innermost active recursion.

(DEFINE)

In this case, the yes-pattern is never directly executed, and no no-pattern is allowed. Similar in spirit to (?{0}) but more efficient. See below for details.

For example:

m{ ( \( )?
   [^()]+
   (?(1) \) )
 }x

matches a chunk of non-parentheses, possibly included in parentheses themselves.

A special form is the (DEFINE) predicate, which never executes its yes-pattern directly, and does not allow a no-pattern. This allows one to define subpatterns which will be executed only by the recursion mechanism. This way, you can define a set of regular expression rules that can be bundled into any pattern you choose.

It is recommended that for this usage you put the DEFINE block at the end of the pattern, and that you name any subpatterns defined within it.

Also, it's worth noting that patterns defined this way probably will not be as efficient, as the optimiser is not very clever about handling them.

An example of how this might be used is as follows:

/(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
 (?(DEFINE)
   (?<NAME_PAT>....)
   (?<ADRESS_PAT>....)
 )/x

Note that capture groups matched inside of recursion are not accessible after the recursion returns, so the extra layer of capturing groups is necessary. Thus $+{NAME_PAT} would not be defined even though $+{NAME} would be.

Finally, keep in mind that subpatterns created inside a DEFINE block count towards the absolute and relative number of captures, so this:

my @captures = "a" =~ /(.)                  # First capture
                       (?(DEFINE)
                           (?<EXAMPLE> 1 )  # Second capture
                       )/x;
say scalar @captures;

Will output 2, not 1. This is particularly important if you intend to compile the definitions with the qr// operator, and later interpolate them in another pattern.

(?>pattern)

An "independent" subexpression, one which matches the substring that a standalone pattern would match if anchored at the given position, and it matches nothing other than this substring. This construct is useful for optimizations of what would otherwise be "eternal" matches, because it will not backtrack (see "Backtracking"). It may also be useful in places where the "grab all you can, and do not give anything back" semantic is desirable.

For example: ^(?>a*)ab will never match, since (?>a*) (anchored at the beginning of string, as above) will match all characters a at the beginning of string, leaving no a for ab to match. In contrast, a*ab will match the same as a+b, since the match of the subgroup a* is influenced by the following group ab (see "Backtracking"). In particular, a* inside a*ab will match fewer characters than a standalone a*, since this makes the tail match.

(?>pattern) does not disable backtracking altogether once it has matched. It is still possible to backtrack past the construct, but not into it. So ((?>a*)|(?>b*))ar will still match "bar".

An effect similar to (?>pattern) may be achieved by writing (?=(pattern))\g{-1}. This matches the same substring as a standalone a+, and the following \g{-1} eats the matched string; it therefore makes a zero-length assertion into an analogue of (?>...). (The difference between these two constructs is that the second one uses a capturing group, thus shifting ordinals of backreferences in the rest of a regular expression.)

Consider this pattern:

m{ \(
      (
        [^()]+           # x+
      |
        \( [^()]* \)
      )+
   \)
 }x

That will efficiently match a nonempty group with matching parentheses two levels deep or less. However, if there is no such group, it will take virtually forever on a long string. That's because there are so many different ways to split a long string into several substrings. This is what (.+)+ is doing, and (.+)+ is similar to a subpattern of the above pattern. Consider how the pattern above detects no-match on ((()aaaaaaaaaaaaaaaaaa in several seconds, but that each extra letter doubles this time. This exponential performance will make it appear that your program has hung. However, a tiny change to this pattern

m{ \(
      (
        (?> [^()]+ )        # change x+ above to (?> x+ )
      |
        \( [^()]* \)
      )+
   \)
 }x

which uses (?>...) matches exactly when the one above does (verifying this yourself would be a productive exercise), but finishes in a fourth the time when used on a similar string with 1000000 as. Be aware, however, that, when this construct is followed by a quantifier, it currently triggers a warning message under the use warnings pragma or -w switch saying it "matches null string many times in regex".

On simple groups, such as the pattern (?> [^()]+ ), a comparable effect may be achieved by negative look-ahead, as in [^()]+ (?! [^()] ). This was only 4 times slower on a string with 1000000 as.

The "grab all you can, and do not give anything back" semantic is desirable in many situations where on the first sight a simple ()* looks like the correct solution. Suppose we parse text with comments being delimited by # followed by some optional (horizontal) whitespace. Contrary to its appearance, #[ \t]* is not the correct subexpression to match the comment delimiter, because it may "give up" some whitespace if the remainder of the pattern can be made to match that way. The correct answer is either one of these:

(?>#[ \t]*)
#[ \t]*(?![ \t])

For example, to grab non-empty comments into $1, one should use either one of these:

/ (?> \# [ \t]* ) (        .+ ) /x;
/     \# [ \t]*   ( [^ \t] .* ) /x;

Which one you pick depends on which of these expressions better reflects the above specification of comments.

In some literature this construct is called "atomic matching" or "possessive matching".

Possessive quantifiers are equivalent to putting the item they are applied to inside of one of these constructs. The following equivalences apply:

Quantifier Form     Bracketing Form
---------------     ---------------
PAT*+               (?>PAT*)
PAT++               (?>PAT+)
PAT?+               (?>PAT?)
PAT{min,max}+       (?>PAT{min,max})

(?[ ])

See "Extended Bracketed Character Classes" in perlrecharclass.

Special Backtracking Control Verbs

WARNING: These patterns are experimental and subject to change or removal in a future version of Perl. Their usage in production code should be noted to avoid problems during upgrades.

These special patterns are generally of the form (*VERB:ARG). Unless otherwise stated the ARG argument is optional; in some cases, it is forbidden.

Any pattern containing a special backtracking verb that allows an argument has the special behaviour that when executed it sets the current package's $REGERROR and $REGMARK variables. When doing so the following rules apply:

On failure, the $REGERROR variable will be set to the ARG value of the verb pattern, if the verb was involved in the failure of the match. If the ARG part of the pattern was omitted, then $REGERROR will be set to the name of the last (*MARK:NAME) pattern executed, or to TRUE if there was none. Also, the $REGMARK variable will be set to FALSE.

On a successful match, the $REGERROR variable will be set to FALSE, and the $REGMARK variable will be set to the name of the last (*MARK:NAME) pattern executed. See the explanation for the (*MARK:NAME) verb below for more details.

NOTE: $REGERROR and $REGMARK are not magic variables like $1 and most other regex-related variables. They are not local to a scope, nor readonly, but instead are volatile package variables similar to $AUTOLOAD. Use local to localize changes to them to a specific scope if necessary.

If a pattern does not contain a special backtracking verb that allows an argument, then $REGERROR and $REGMARK are not touched at all.

Verbs that take an argument

(*PRUNE) (*PRUNE:NAME)

This zero-width pattern prunes the backtracking tree at the current point when backtracked into on failure. Consider the pattern A (*PRUNE) B, where A and B are complex patterns. Until the (*PRUNE) verb is reached, A may backtrack as necessary to match. Once it is reached, matching continues in B, which may also backtrack as necessary; however, should B not match, then no further backtracking will take place, and the pattern will fail outright at the current starting position.

The following example counts all the possible matching strings in a pattern (without actually matching any of them).

'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
print "Count=$count\n";

which produces:

aaab
aaa
aa
a
aab
aa
a
ab
a
Count=9

If we add a (*PRUNE) before the count like the following

'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
print "Count=$count\n";

we prevent backtracking and find the count of the longest matching string at each matching starting point like so:

aaab
aab
ab
Count=3

Any number of (*PRUNE) assertions may be used in a pattern.

See also (?>pattern) and possessive quantifiers for other ways to control backtracking. In some cases, the use of (*PRUNE) can be replaced with a (?>pattern) with no functional difference; however, (*PRUNE) can be used to handle cases that cannot be expressed using a (?>pattern) alone.

(*SKIP) (*SKIP:NAME)

This zero-width pattern is similar to (*PRUNE), except that on failure it also signifies that whatever text that was matched leading up to the (*SKIP) pattern being executed cannot be part of any match of this pattern. This effectively means that the regex engine "skips" forward to this position on failure and tries to match again, (assuming that there is sufficient room to match).

The name of the (*SKIP:NAME) pattern has special significance. If a (*MARK:NAME) was encountered while matching, then it is that position which is used as the "skip point". If no (*MARK) of that name was encountered, then the (*SKIP) operator has no effect. When used without a name the "skip point" is where the match point was when executing the (*SKIP) pattern.

Compare the following to the examples in (*PRUNE); note the string is twice as long:

'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
print "Count=$count\n";

outputs

aaab
aaab
Count=2

Once the 'aaab' at the start of the string has matched, and the (*SKIP) executed, the next starting point will be where the cursor was when the (*SKIP) was executed.

(*MARK:NAME) (*:NAME)

This zero-width pattern can be used to mark the point reached in a string when a certain part of the pattern has been successfully matched. This mark may be given a name. A later (*SKIP) pattern will then skip forward to that point if backtracked into on failure. Any number of (*MARK) patterns are allowed, and the NAME portion may be duplicated.

In addition to interacting with the (*SKIP) pattern, (*MARK:NAME) can be used to "label" a pattern branch, so that after matching, the program can determine which branches of the pattern were involved in the match.

When a match is successful, the $REGMARK variable will be set to the name of the most recently executed (*MARK:NAME) that was involved in the match.

This can be used to determine which branch of a pattern was matched without using a separate capture group for each branch, which in turn can result in a performance improvement, as perl cannot optimize /(?:(x)|(y)|(z))/ as efficiently as something like /(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/.

When a match has failed, and unless another verb has been involved in failing the match and has provided its own name to use, the $REGERROR variable will be set to the name of the most recently executed (*MARK:NAME).

See "(*SKIP)" for more details.

As a shortcut (*MARK:NAME) can be written (*:NAME).

(*THEN) (*THEN:NAME)

This is similar to the "cut group" operator :: from Perl 6. Like (*PRUNE), this verb always matches, and when backtracked into on failure, it causes the regex engine to try the next alternation in the innermost enclosing group (capturing or otherwise) that has alternations. The two branches of a (?(condition)yes-pattern|no-pattern) do not count as an alternation, as far as (*THEN) is concerned.

Its name comes from the observation that this operation combined with the alternation operator (|) can be used to create what is essentially a pattern-based if/then/else block:

( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )

Note that if this operator is used and NOT inside of an alternation then it acts exactly like the (*PRUNE) operator.

/ A (*PRUNE) B /

is the same as

/ A (*THEN) B /

but

/ ( A (*THEN) B | C ) /

is not the same as

/ ( A (*PRUNE) B | C ) /

as after matching the A but failing on the B the (*THEN) verb will backtrack and try C; but the (*PRUNE) verb will simply fail.

Verbs without an argument

(*COMMIT)

This is the Perl 6 "commit pattern" <commit> or :::. It's a zero-width pattern similar to (*SKIP), except that when backtracked into on failure it causes the match to fail outright. No further attempts to find a valid match by advancing the start pointer will occur again. For example,

'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
print "Count=$count\n";

outputs

aaab
Count=1

In other words, once the (*COMMIT) has been entered, and if the pattern does not match, the regex engine will not try any further matching on the rest of the string.

(*FAIL) (*F)

This pattern matches nothing and always fails. It can be used to force the engine to backtrack. It is equivalent to (?!), but easier to read. In fact, (?!) gets optimised into (*FAIL) internally.

It is probably useful only when combined with (?{}) or (??{}).

(*ACCEPT)

WARNING: This feature is highly experimental. It is not recommended for production code.

This pattern matches nothing and causes the end of successful matching at the point at which the (*ACCEPT) pattern was encountered, regardless of whether there is actually more to match in the string. When inside of a nested pattern, such as recursion, or in a subpattern dynamically generated via (??{}), only the innermost pattern is ended immediately.

If the (*ACCEPT) is inside of capturing groups then the groups are marked as ended at the point at which the (*ACCEPT) was encountered. For instance:

'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;

will match, and $1 will be AB and $2 will be B, $3 will not be set. If another branch in the inner parentheses was matched, such as in the string 'ACDE', then the D and E would have to be matched as well.

Backtracking

NOTE: This section presents an abstract approximation of regular expression behavior. For a more rigorous (and complicated) view of the rules involved in selecting a match among possible alternatives, see "Combining RE Pieces".

A fundamental feature of regular expression matching involves the notion called backtracking, which is currently used (when needed) by all regular non-possessive expression quantifiers, namely *, *?, +, +?, {n,m}, and {n,m}?. Backtracking is often optimized internally, but the general principle outlined here is valid.

For a regular expression to match, the entire regular expression must match, not just part of it. So if the beginning of a pattern containing a quantifier succeeds in a way that causes later parts in the pattern to fail, the matching engine backs up and recalculates the beginning part--that's why it's called backtracking.

Here is an example of backtracking: Let's say you want to find the word following "foo" in the string "Food is on the foo table.":

$_ = "Food is on the foo table.";
if ( /\b(foo)\s+(\w+)/i ) {
    print "$2 follows $1.\n";
}

When the match runs, the first part of the regular expression (\b(foo)) finds a possible match right at the beginning of the string, and loads up $1 with "Foo". However, as soon as the matching engine sees that there's no whitespace following the "Foo" that it had saved in $1, it realizes its mistake and starts over again one character after where it had the tentative match. This time it goes all the way until the next occurrence of "foo". The complete regular expression matches this time, and you get the expected output of "table follows foo."

Sometimes minimal matching can help a lot. Imagine you'd like to match everything between "foo" and "bar". Initially, you write something like this:

$_ =  "The food is under the bar in the barn.";
if ( /foo(.*)bar/ ) {
    print "got <$1>\n";
}

Which perhaps unexpectedly yields:

got <d is under the bar in the >

That's because .* was greedy, so you get everything between the first "foo" and the last "bar". Here it's more effective to use minimal matching to make sure you get the text between a "foo" and the first "bar" thereafter.

  if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
got <d is under the >

Here's another example. Let's say you'd like to match a number at the end of a string, and you also want to keep the preceding part of the match. So you write this:

$_ = "I have 2 numbers: 53147";
if ( /(.*)(\d*)/ ) {                                # Wrong!
    print "Beginning is <$1>, number is <$2>.\n";
}

That won't work at all, because .* was greedy and gobbled up the whole string. As \d* can match on an empty string the complete regular expression matched successfully.

Beginning is <I have 2 numbers: 53147>, number is <>.

Here are some variants, most of which don't work:

$_ = "I have 2 numbers: 53147";
@pats = qw{
    (.*)(\d*)
    (.*)(\d+)
    (.*?)(\d*)
    (.*?)(\d+)
    (.*)(\d+)$
    (.*?)(\d+)$
    (.*)\b(\d+)$
    (.*\D)(\d+)$
};

for $pat (@pats) {
    printf "%-12s ", $pat;
    if ( /$pat/ ) {
        print "<$1> <$2>\n";
    } else {
        print "FAIL\n";
    }
}

That will print out:

(.*)(\d*)    <I have 2 numbers: 53147> <>
(.*)(\d+)    <I have 2 numbers: 5314> <7>
(.*?)(\d*)   <> <>
(.*?)(\d+)   <I have > <2>
(.*)(\d+)$   <I have 2 numbers: 5314> <7>
(.*?)(\d+)$  <I have 2 numbers: > <53147>
(.*)\b(\d+)$ <I have 2 numbers: > <53147>
(.*\D)(\d+)$ <I have 2 numbers: > <53147>

As you see, this can be a bit tricky. It's important to realize that a regular expression is merely a set of assertions that gives a definition of success. There may be 0, 1, or several different ways that the definition might succeed against a particular string. And if there are multiple ways it might succeed, you need to understand backtracking to know which variety of success you will achieve.

When using look-ahead assertions and negations, this can all get even trickier. Imagine you'd like to find a sequence of non-digits not followed by "123". You might try to write that as

$_ = "ABC123";
if ( /^\D*(?!123)/ ) {                # Wrong!
    print "Yup, no 123 in $_\n";
}

But that isn't going to match; at least, not the way you're hoping. It claims that there is no 123 in the string. Here's a clearer picture of why that pattern matches, contrary to popular expectations:

$x = 'ABC123';
$y = 'ABC445';

print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;

print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;

This prints

2: got ABC
3: got AB
4: got ABC

You might have expected test 3 to fail because it seems to a more general purpose version of test 1. The important difference between them is that test 3 contains a quantifier (\D*) and so can use backtracking, whereas test 1 will not. What's happening is that you've asked "Is it true that at the start of $x, following 0 or more non-digits, you have something that's not 123?" If the pattern matcher had let \D* expand to "ABC", this would have caused the whole pattern to fail.

The search engine will initially match \D* with "ABC". Then it will try to match (?!123) with "123", which fails. But because a quantifier (\D*) has been used in the regular expression, the search engine can backtrack and retry the match differently in the hope of matching the complete regular expression.

The pattern really, really wants to succeed, so it uses the standard pattern back-off-and-retry and lets \D* expand to just "AB" this time. Now there's indeed something following "AB" that is not "123". It's "C123", which suffices.

We can deal with this by using both an assertion and a negation. We'll say that the first part in $1 must be followed both by a digit and by something that's not "123". Remember that the look-aheads are zero-width expressions--they only look, but don't consume any of the string in their match. So rewriting this way produces what you'd expect; that is, case 5 will fail, but case 6 succeeds:

print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;

6: got ABC

In other words, the two zero-width assertions next to each other work as though they're ANDed together, just as you'd use any built-in assertions: /^$/ matches only if you're at the beginning of the line AND the end of the line simultaneously. The deeper underlying truth is that juxtaposition in regular expressions always means AND, except when you write an explicit OR using the vertical bar. /ab/ means match "a" AND (then) match "b", although the attempted matches are made at different positions because "a" is not a zero-width assertion, but a one-width assertion.

WARNING: Particularly complicated regular expressions can take exponential time to solve because of the immense number of possible ways they can use backtracking to try for a match. For example, without internal optimizations done by the regular expression engine, this will take a painfully long time to run:

'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/

And if you used *'s in the internal groups instead of limiting them to 0 through 5 matches, then it would take forever--or until you ran out of stack space. Moreover, these internal optimizations are not always applicable. For example, if you put {0,5} instead of * on the external group, no current optimization is applicable, and the match takes a long time to finish.

A powerful tool for optimizing such beasts is what is known as an "independent group", which does not backtrack (see "(?>pattern)"). Note also that zero-length look-ahead/look-behind assertions will not backtrack to make the tail match, since they are in "logical" context: only whether they match is considered relevant. For an example where side-effects of look-ahead might have influenced the following match, see "(?>pattern)".

Version 8 Regular Expressions

In case you're not familiar with the "regular" Version 8 regex routines, here are the pattern-matching rules not described above.

Any single character matches itself, unless it is a metacharacter with a special meaning described here or above. You can cause characters that normally function as metacharacters to be interpreted literally by prefixing them with a "\" (e.g., "\." matches a ".", not any character; "\\" matches a "\"). This escape mechanism is also required for the character used as the pattern delimiter.

A series of characters matches that series of characters in the target string, so the pattern blurfl would match "blurfl" in the target string.

You can specify a character class, by enclosing a list of characters in [], which will match any character from the list. If the first character after the "[" is "^", the class matches any character not in the list. Within a list, the "-" character specifies a range, so that a-z represents all characters between "a" and "z", inclusive. If you want either "-" or "]" itself to be a member of a class, put it at the start of the list (possibly after a "^"), or escape it with a backslash. "-" is also taken literally when it is at the end of the list, just before the closing "]". (The following all specify the same class of three characters: [-az], [az-], and [a\-z]. All are different from [a-z], which specifies a class containing twenty-six characters, even on EBCDIC-based character sets.) Also, if you try to use the character classes \w, \W, \s, \S, \d, or \D as endpoints of a range, the "-" is understood literally.

Note also that the whole range idea is rather unportable between character sets--and even within character sets they may cause results you probably didn't expect. A sound principle is to use only ranges that begin from and end at either alphabetics of equal case ([a-e], [A-E]), or digits ([0-9]). Anything else is unsafe. If in doubt, spell out the character sets in full.

Characters may be specified using a metacharacter syntax much like that used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return, "\f" a form feed, etc. More generally, \nnn, where nnn is a string of three octal digits, matches the character whose coded character set value is nnn. Similarly, \xnn, where nn are hexadecimal digits, matches the character whose ordinal is nn. The expression \cx matches the character control-x. Finally, the "." metacharacter matches any character except "\n" (unless you use /s).

You can specify a series of alternatives for a pattern using "|" to separate them, so that fee|fie|foe will match any of "fee", "fie", or "foe" in the target string (as would f(e|i|o)e). The first alternative includes everything from the last pattern delimiter ("(", "(?:", etc. or the beginning of the pattern) up to the first "|", and the last alternative contains everything from the last "|" to the next closing pattern delimiter. That's why it's common practice to include alternatives in parentheses: to minimize confusion about where they start and end.

Alternatives are tried from left to right, so the first alternative found for which the entire expression matches, is the one that is chosen. This means that alternatives are not necessarily greedy. For example: when matching foo|foot against "barefoot", only the "foo" part will match, as that is the first alternative tried, and it successfully matches the target string. (This might not seem important, but it is important when you are capturing matched text using parentheses.)

Also remember that "|" is interpreted as a literal within square brackets, so if you write [fee|fie|foe] you're really only matching [feio|].

Within a pattern, you may designate subpatterns for later reference by enclosing them in parentheses, and you may refer back to the nth subpattern later in the pattern using the metacharacter \n or \gn. Subpatterns are numbered based on the left to right order of their opening parenthesis. A backreference matches whatever actually matched the subpattern in the string being examined, not the rules for that subpattern. Therefore, (0|0x)\d*\s\g1\d* will match "0x1234 0x4321", but not "0x1234 01234", because subpattern 1 matched "0x", even though the rule 0|0x could potentially match the leading 0 in the second number.

Warning on \1 Instead of $1

Some people get too used to writing things like:

$pattern =~ s/(\W)/\\\1/g;

This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid shocking the sed addicts, but it's a dirty habit to get into. That's because in PerlThink, the righthand side of an s/// is a double-quoted string. \1 in the usual double-quoted string means a control-A. The customary Unix meaning of \1 is kludged in for s///. However, if you get into the habit of doing that, you get yourself into trouble if you then add an /e modifier.

s/(\d+)/ \1 + 1 /eg;            # causes warning under -w

Or if you try to do

s/(\d+)/\1000/;

You can't disambiguate that by saying \{1}000, whereas you can fix it with ${1}000. The operation of interpolation should not be confused with the operation of matching a backreference. Certainly they mean two different things on the left side of the s///.

Repeated Patterns Matching a Zero-length Substring

WARNING: Difficult material (and prose) ahead. This section needs a rewrite.

Regular expressions provide a terse and powerful programming language. As with most other power tools, power comes together with the ability to wreak havoc.

A common abuse of this power stems from the ability to make infinite loops using regular expressions, with something as innocuous as:

'foo' =~ m{ ( o? )* }x;

The o? matches at the beginning of 'foo', and since the position in the string is not moved by the match, o? would match again and again because of the * quantifier. Another common way to create a similar cycle is with the looping modifier //g:

@matches = ( 'foo' =~ m{ o? }xg );

or

print "match: <$&>\n" while 'foo' =~ m{ o? }xg;

or the loop implied by split().

However, long experience has shown that many programming tasks may be significantly simplified by using repeated subexpressions that may match zero-length substrings. Here's a simple example being:

@chars = split //, $string;           # // is not magic in split
($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /

Thus Perl allows such constructs, by forcefully breaking the infinite loop. The rules for this are different for lower-level loops given by the greedy quantifiers *+{}, and for higher-level ones like the /g modifier or split() operator.

The lower-level loops are interrupted (that is, the loop is broken) when Perl detects that a repeated expression matched a zero-length substring. Таким образом

m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;

is made equivalent to

m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;

For example, this program

#!perl -l
"aaaaab" =~ /
  (?:
     a                 # non-zero
     |                 # or
    (?{print "hello"}) # print hello whenever this
                       #    branch is tried
    (?=(b))            # zero-width assertion
  )*  # any number of times
 /x;
print $&;
print $1;

prints

hello
aaaaa
b

Notice that "hello" is only printed once, as when Perl sees that the sixth iteration of the outermost (?:)* matches a zero-length string, it stops the *.

The higher-level loops preserve an additional state between iterations: whether the last match was zero-length. To break the loop, the following match after a zero-length match is prohibited to have a length of zero. This prohibition interacts with backtracking (see "Backtracking"), and so the second best match is chosen if the best match is of zero length.

For example:

$_ = 'bar';
s/\w??/<$&>/g;

results in <><b><><a><><r><>. At each position of the string the best match given by non-greedy ?? is the zero-length match, and the second best match is what is matched by \w. Thus zero-length matches alternate with one-character-long matches.

Similarly, for repeated m/()/g the second-best match is the match at the position one notch further in the string.

The additional state of being matched with zero-length is associated with the matched string, and is reset by each assignment to pos(). Zero-length matches at the end of the previous match are ignored during split.

Combining RE Pieces

Each of the elementary pieces of regular expressions which were described before (such as ab or \Z) could match at most one substring at the given position of the input string. However, in a typical regular expression these elementary pieces are combined into more complicated patterns using combining operators ST, S|T, S* etc. (in these examples S and T are regular subexpressions).

Such combinations can include alternatives, leading to a problem of choice: if we match a regular expression a|ab against "abc", will it match substring "a" or "ab"? One way to describe which substring is actually matched is the concept of backtracking (see "Backtracking"). However, this description is too low-level and makes you think in terms of a particular implementation.

Another description starts with notions of "better"/"worse". All the substrings which may be matched by the given regular expression can be sorted from the "best" match to the "worst" match, and it is the "best" match which is chosen. This substitutes the question of "what is chosen?" by the question of "which matches are better, and which are worse?".

Again, for elementary pieces there is no such question, since at most one match at a given position is possible. This section describes the notion of better/worse for combining operators. In the description below S and T are regular subexpressions.

ST

Consider two possible matches, AB and A'B', A and A' are substrings which can be matched by S, B and B' are substrings which can be matched by T.

If A is a better match for S than A', AB is a better match than A'B'.

If A and A' coincide: AB is a better match than AB' if B is a better match for T than B'.

S|T

When S can match, it is a better match than when only T can match.

Ordering of two matches for S is the same as for S. Similar for two matches for T.

S{REPEAT_COUNT}

Matches as SSS...S (repeated as many times as necessary).

S{min,max}

Matches as S{max}|S{max-1}|...|S{min+1}|S{min}.

S{min,max}?

Matches as S{min}|S{min+1}|...|S{max-1}|S{max}.

S?, S*, S+

Same as S{0,1}, S{0,BIG_NUMBER}, S{1,BIG_NUMBER} respectively.

S??, S*?, S+?

Same as S{0,1}?, S{0,BIG_NUMBER}?, S{1,BIG_NUMBER}? respectively.

(?>S)

Matches the best match for S and only that.

(?=S), (?<=S)

Only the best match for S is considered. (This is important only if S has capturing parentheses, and backreferences are used somewhere else in the whole regular expression.)

(?!S), (?<!S)

For this grouping operator there is no need to describe the ordering, since only whether or not S can match is important.

(??{ EXPR }), (?PARNO)

The ordering is the same as for the regular expression which is the result of EXPR, or the pattern contained by capture group PARNO.

(?(condition)yes-pattern|no-pattern)

Recall that which of yes-pattern or no-pattern actually matches is already determined. The ordering of the matches is the same as for the chosen subexpression.

The above recipes describe the ordering of matches at a given position. One more rule is needed to understand how a match is determined for the whole regular expression: a match at an earlier position is always better than a match at a later position.

Creating Custom RE Engines

As of Perl 5.10.0, one can create custom regular expression engines. This is not for the faint of heart, as they have to plug in at the C level. See perlreapi for more details.

As an alternative, overloaded constants (see overload) provide a simple way to extend the functionality of the RE engine, by substituting one pattern for another.

Suppose that we want to enable a new RE escape-sequence \Y| which matches at a boundary between whitespace characters and non-whitespace characters. Note that (?=\S)(?<!\S)|(?!\S)(?<=\S) matches exactly at these positions, so we want to have each \Y| in the place of the more complicated version. We can create a module customre to do this:

package customre;
use overload;

sub import {
  shift;
  die "No argument to customre::import allowed" if @_;
  overload::constant 'qr' => \&convert;
}

sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}

# We must also take care of not escaping the legitimate \\Y|
# sequence, hence the presence of '\\' in the conversion rules.
my %rules = ( '\\' => '\\\\',
              'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
sub convert {
  my $re = shift;
  $re =~ s{
            \\ ( \\ | Y . )
          }
          { $rules{$1} or invalid($re,$1) }sgex;
  return $re;
}

Now use customre enables the new escape in constant regular expressions, i.e., those without any runtime variable interpolations. As documented in overload, this conversion will work only over literal parts of regular expressions. For \Y|$re\Y| the variable part of this regular expression needs to be converted explicitly (but only if the special meaning of \Y| should be enabled inside $re):

use customre;
$re = <>;
chomp $re;
$re = customre::convert $re;
/\Y|$re\Y|/;

PCRE/Python Support

As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions to the regex syntax. While Perl programmers are encouraged to use the Perl-specific syntax, the following are also accepted:

(?P<NAME>pattern)

Define a named capture group. Equivalent to (?<NAME>pattern).

(?P=NAME)

Backreference to a named capture group. Equivalent to \g{NAME}.

(?P>NAME)

Subroutine call to a named capture group. Equivalent to (?&NAME).

BUGS

Many regular expression constructs don't work on EBCDIC platforms.

There are a number of issues with regard to case-insensitive matching in Unicode rules. See i under "Modifiers" above.

This document varies from difficult to understand to completely and utterly opaque. The wandering prose riddled with jargon is hard to fathom in several places.

This document needs a rewrite that separates the tutorial content from the reference content.

SEE ALSO

perlrequick.

perlretut.

"Regexp Quote-Like Operators" in perlop.

"Gory details of parsing quoted constructs" in perlop.

perlfaq6.

"pos" in perlfunc.

perllocale.

perlebcdic.

Mastering Regular Expressions by Jeffrey Friedl, published by O'Reilly and Associates.

ПЕРЕВОДЧИКИ

• Николай Мишин <mi@ya.ru>

cpanm POD2::RU

perl -MCPAN -e shell
install POD2::RU