NAME

Test::Builder::Tester - test testsuites that have been built with Test::Builder

SYNOPSIS

use Test::Builder::Tester tests => 1;
use Test::More;

test_out("not ok 1 - foo");
test_err("#     Failed test ($0 at line ".line_num(+1).")");
fail("foo");
test_test("fail works");

DESCRIPTION

A module that helps you test test modules that are built with Test::Builder.

Basically, the system works by performing a three step process for each test you wish to test. This starts with using 'test_out' and 'test_err' in advance to declare what the testsuite you are testing will output with Test::Builder to it's stdout and stderr.

You then can run the test(s) from your test suite that call Test::Builder. The output of Test::Builder is captured by Test::Builder::Tester rather than going to its usual destination.

The final stage is to call test_test that will simply compare what you predeclared to what Test::Builder actually outputted, and report the results back with a "ok" or "not ok" (with debugging) to the normal output.

Methods

These are the six methods that are exported as default.

test_out

test_err

Procedures for predeclaring the output that your test suite is expected to produce until test_test is called. These procedures automatically assume that each line terminates with "\n". So

test_out("ok 1","ok 2");

is the same as

test_out("ok 1\nok 2");

which is even the same as

test_out("ok 1");
test_out("ok 2");

Once test_out, test_err, test_fail or test_diag have been called all output from Test::Builder will be captured by Test::Builder::Tester. This means that your will not be able perform further tests to the normal output in the normal way until you call test_test (well, unless you manually meddle with the output filehandles)

test_fail

Because the standard failure message that Test::Builder produces whenever a test fails will be a common occurrence in your test error output, rather than forcing you to call test_err with the string all the time like so

test_err("#     Failed test ($0 at line ".line_num(+1).")");

test_fail exists as a convenience method that can be called instead. It takes one argument, the offset from the current line that the line that causes the fail is on.

test_fail(+1);

This means that the example in the synopsis could be rewritten more simply as:

test_out("not ok 1 - foo");
test_fail(+1);
fail("foo");
test_test("fail works");

test_diag

As most of your output to the error stream will be performed by Test::Builder's diag function which prepends comment hashes and spacing to the start of the output Test::Builder::Tester provides the test_diag function that auotmatically adds the output onto the front. So instead of writing

test_err("#     Couldn't open file");

you can write

test_diag("Couldn't open file");

Remember that Test::Builder's diag function will not add newlines to the end of output and test_diag will. So to check

Test::Builder->new->diag("foo\n","bar\n");

You would do

test_diag("foo","bar")

without the newlines.

test_test

Actually performs the output check testing the tests, comparing the data (with 'eq') that we have captured from Test::Builder against that that was declared with test_out and test_err.

Optionally takes a name for the test as its only argument.

Once test_test has been run test output will be redirected back to the original filehandles that Test::Builder was connected to (probably STDOUT and STDERR)

line_num

A utility function that returns the line number that the function was called on. You can pass it an offset which will be added to the result. This is very useful for working out what the correct diagnostic methods should contain when they mention line numbers.

In addition there exists one function that is not exported.

color

When test_test is called and the output that your tests generate does not match that which you declared, test_test will print out debug information showing the two conflicting versions. As this output itself is debug information it can be confusing which part of the output is from test_test and which is from your original tests.

To assist you, if you have the Term::ANSIColor module installed (which you will do by default on perl 5.005 onwards), test_test can use colour to disambiguate the different types of output. This will cause the output that was originally from the tests you are testing to be coloured green and red. The green part represents the text which is the same between the executed and actual output, the red shows which part differs.

The color function determines if colouring should occur or not. Passing it a true or false value will enable and disable colouring respectively, and the function called with no argument will return the current setting.

To enable colouring from the command line, you can use the Text::Builder::Tester::Color module like so:

perl -Mlib=Text::Builder::Tester::Color test.t

BUGS

Calls Test::Builder's no_ending method turning off the ending tests. This is needed as otherwise it will trip out because we've run more tests than we strictly should have and it'll register any failures we had that we were testing for as real failures.

The color function doesn't work unless Term::ANSIColor is installed and is compatible with your terminal.

AUTHOR

Copyright Mark Fowler <mark@twoshortplanks.com> 2002.

Some code taken from Test::More and Test::Catch, written by by Michael G Schwern <schwern@pobox.com>. Hence, those parts Copyright Micheal G Schwern 2001. Used and distributed with permission.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

SEE ALSO

Test::Builder, Test::Builder::Tester::Color, Test::More.