/ 
Digest-SHA-4.0.2
River stage four • 407 direct dependents • 8982 total dependents
/ Digest::SHA

NAME

Digest::SHA - Perl extension for SHA-1/256/384/512

SYNOPSIS

# Functional style
use Digest::SHA qw(sha1 sha1_hex sha1_base64 sha256 sha256_hex ... );

$digest = sha1($data);
$digest = sha1_hex($data);
$digest = sha1_base64($data);


# OO style
use Digest::SHA;

$sha = Digest::SHA->new($alg);		# alg = 1, 256, 384, 512

$sha->add($data);
$sha->add_bits($data, $nbits);
$sha->add_bits($bits);
$sha->addfile(*FILE);

$digest = $sha->digest;
$digest = $sha->hexdigest;
$digest = $sha->b64digest;

ABSTRACT

Digest::SHA implements all four algorithms of the NIST Secure Hash Standard: SHA-1, SHA-256, SHA-384, and SHA-512. The module is capable of calculating digest values of bit-wise as well as byte-wise messages.

DESCRIPTION

Digest::SHA provides a complete and portable implementation of the NIST Secure Hash Standard. It offers two different ways to calculate digests: all-at-once, or in stages. The following program calculates the SHA-256 digest of "hello world" using each method:

use Digest::SHA ':all';

$data = "hello world";
@frags = split(//, $data);

# all-at-once (Functional style)
$digest1 = sha256_hex($data);

# in-stages (OO style)
$state = Digest::SHA->new(256);
for (@frags) { $state->add($_) }
$digest2 = $state->hexdigest;

print $digest1 eq $digest2 ?
	"whew!\n" : "career in aluminum siding\n";

To compute the digest of an n-bit message where n is not a multiple of 8, use the add_bits() method. As an example, consider the 446-bit message consisting of the fragment "110" repeated 148 times, followed by the fragment "11". Here's how to calculate its SHA-1 digest:

$bits = "110" x 148 . "11";
$digest = Digest::SHA->new(1)->add_bits($bits)->hexdigest;

Note that for larger bit-strings, it's more efficient to use the two-argument version add_bits($data, $nbits), where $data is in the customary packed binary format used for Perl strings.

As a temporary convenience, the Digest::SHA module provides self-contained routines to calculate HMAC-SHA-1/256/384/512 digests. These services exist in functional form only, and closely mimic the style and behavior of the shaX, shaX_hex, and shaX_base64 functions. It's expected that they will be moved to an appropriate Digest::HMAC module as soon as the corresponding OO implementation is developed and tested.

EXPORT

None by default.

EXPORTABLE FUNCTIONS

    Provided your C compiler supports the "long long" type, all of these functions will be available for use. If it doesn't, you won't be able to perform the SHA-384 and SHA-512 transforms, both of which require portable 64-bit operations.

Functional style

sha1($data, ...)
sha256($data, ...)
sha384($data, ...)
sha512($data, ...)

Joins the arguments into a single string, and returns its SHA-1/256/384/512 digest encoded as a binary string.

sha1_hex($data, ...)
sha256_hex($data, ...)
sha384_hex($data, ...)
sha512_hex($data, ...)

Joins the arguments into a single string, and returns its SHA-1/256/384/512 digest encoded as a hexadecimal string.

sha1_base64($data, ...)
sha256_base64($data, ...)
sha384_base64($data, ...)
sha512_base64($data, ...)

Joins the arguments into a single string, and returns its SHA-1/256/384/512 digest encoded as a Base64 string.

OO style

$sha = Digest::SHA->new($alg)

Returns a new Digest::SHA object. Permissible values for $alg are 1, 256, 384, and 512. However, it's also possible to use common string representations of the algorithm (e.g. "sha256", "SHA-384"). If the argument is missing, SHA-1 will be used by default.

Invoking "new" as an instance method will not cause a new object to be created, but will simply reset the object to the initial state associated with $alg. If the argument is missing, the object will continue using the same algorithm that was selected at creation.

$sha->reset($alg)

This method has exactly the same effect as $sha->new($alg). In fact, "reset" is just an alias for "new".

$sha->hashsize

Returns the number of digest bits for this object. The values are 160, 256, 384, and 512 for SHA-1, SHA-256, SHA-384, and SHA-512, respectively.

$sha->clone

Returns a duplicate copy of the $sha object.

$sha->add($data, ...)

Joins the arguments into a single string, and uses it to update the current $sha digest state. In other words, the following statements have the same effect:

$sha->add("a"); $sha->add("b"); $sha->add("c");
$sha->add("a")->add("b")->add("c");
$sha->add("a", "b", "c");
$sha->add("abc");
$sha->add_bits($data, $nbits)
$sha->add_bits($bits)

Updates the current digest state by appending bits to it. The return value is the updated object itself.

The first form causes the most-significant $nbits of $data to be appended to the stream. The $data argument is in the customary binary format used for Perl strings.

The second form takes an ASCII string of "0" and "1" characters as its argument. It's simply a convenient shorthand for

$sha->add_bits(pack("B*", $bits), length($bits));

So, the following two statements do the same thing:

$ctx->add_bits("111100001010");
$ctx->add_bits("\xF0\xA0", 12);
$sha->addfile(*FILE)

Reads from FILE until EOF, and appends that data to the current $sha state. The return value is the updated $sha object itself.

$sha->dump($filename)

Provides persistent storage of intermediate SHA states by writing a portable, human-readable representation of the current state to $filename. If the argument is missing, or equal to the empty string, the state information will be written to stdout.

$sha->load($filename)

Returns a Digest::SHA object representing the intermediate SHA state that was previously stored to $filename. If called as a class method, a new object is created; if called as an instance method, the object is reset to the state contained in $filename.

$sha->digest

Returns the digest encoded as a binary string.

Note that the digest method is a read-once operation. Once it has been performed, the Digest::SHA object is automatically reset in preparation for calculating another digest value. Call $sha->clone->digest if it's necessary to preserve the original digest state.

$sha->hexdigest

Returns the digest encoded as a hexadecimal string.

Like digest, this method is a read-once operation. Call $sha->clone->hexdigest if it's necessary to preserve the original digest state.

$sha->b64digest

Returns the digest encoded as a Base64 string.

Like digest, this method is a read-once operation. Call $sha->clone->b64digest if it's necessary to preserve the original digest state.

HMAC-SHA-1/256/384/512

hmac_sha1($data, $key)
hmac_sha256($data, $key)
hmac_sha384($data, $key)
hmac_sha512($data, $key)

Returns the HMAC-SHA-1/256/384/512 digest of $data/$key, with the result encoded as a binary string. Multiple $data arguments are allowed, provided that $key is the final argument in the list.

hmac_sha1_hex($data, $key)
hmac_sha256_hex($data, $key)
hmac_sha384_hex($data, $key)
hmac_sha512_hex($data, $key)

Returns the HMAC-SHA-1/256/384/512 digest of $data/$key, with the result encoded as a hexadecimal string. Multiple $data arguments are allowed, provided that $key is the final argument in the list.

hmac_sha1_base64($data, $key)
hmac_sha256_base64($data, $key)
hmac_sha384_base64($data, $key)
hmac_sha512_base64($data, $key)

Returns the HMAC-SHA-1/256/384/512 digest of $data/$key, with the result encoded as a Base64 string. Multiple $data arguments are allowed, provided that $key is the final argument in the list.

SEE ALSO

Digest::, Digest::SHA1

The Secure Hash Standard (FIPS PUB 180-2) can be found at:

http://csrc.nist.gov/publications/fips/fips180-2/fips180-2.pdf

The Keyed-Hash Message Authentication Code (HMAC):

http://csrc.nist.gov/publications/fips/fips198/fips-198a.pdf

AUTHOR

Mark Shelor, <mshelor@comcast.net>

Many thanks to Gisle Aas, Julius Duque, Jeffrey Friedl, and Chris Skiscim for their valuable comments and suggestions.

COPYRIGHT AND LICENSE

Copyright (C) 2003 by Mark Shelor

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.