NAME

Catalyst::Manual::Tutorial::Authorization - Catalyst Tutorial - Part 6: Authorization

OVERVIEW

This is Part 6 of 10 for the Catalyst tutorial.

DESCRIPTION

This part of the tutorial adds role-based authorization to the existing authentication implemented in Part 5. It provides simple examples of how to use roles in both TT templates and controller actions. The first half looks at basic authorization concepts. The second half looks at how moving your authorization code to your model can simplify your code and make things easier to maintain.

You can checkout the source code for this example from the catalyst subversion repository as per the instructions in Catalyst::Manual::Tutorial::Intro.

BASIC AUTHORIZATION

In this section you learn the basics of how authorization works under Catalyst.

Update Plugins to Include Support for Authorization

Edit lib/MyApp.pm and add Authorization::Roles to the list:

# Load plugins
use Catalyst qw/-Debug
            ConfigLoader
            Static::Simple
            
            StackTrace
            
            Authentication
            Authorization::Roles
    
            Session
            Session::Store::FastMmap
            Session::State::Cookie
            /;

Note: As discussed in MoreCatalystBasics, different versions of Catalyst::Devel have used a variety of methods to load the plugins. You can put the plugins in the use Catalyst statement if you prefer.

Add Config Information for Authorization

Edit myapp.conf and update it to match the following (the role_relation and role_field definitions are new):

# rename this file to MyApp.yml and put a : in front of "name" if
# you want to use yaml like in old versions of Catalyst
name MyApp
<authentication>
    default_realm dbic
    <realms>
        <dbic>
            <credential>
                # Note this first definition would be the same as setting
                # __PACKAGE__->config->{authentication}->{realms}->{dbic}
                #     ->{credential} = 'Password' in lib/MyApp.pm
                #
                # Specify that we are going to do password-based auth
                class Password
                # This is the name of the field in the users table with the
                # password stored in it
                password_field password
                # Switch to more secure hashed passwords
                password_type  hashed
                # Use the SHA-1 hashing algorithm
                password_hash_type SHA-1
            </credential>
            <store>
                # Use DBIC to retrieve username, password & role information
                class DBIx::Class
                # This is the model object created by Catalyst::Model::DBIC
                # from your schema (you created 'MyApp::Schema::Result::User'
                # but as the Catalyst startup debug messages show, it was 
                # loaded as 'MyApp::Model::DB::Users').
                # NOTE: Omit 'MyApp::Model' here just as you would when using
                # '$c->model("DB::Users)'
                user_class DB::Users
                # This is the name of a many_to_many relation in the users
                # object that points to the roles for that user
                role_relation  roles
                # This is the name of field in the roles table that contains
                # the role information
                role_field role
            </store>
        </dbic>
    </realms>
</authentication>

Add Role-Specific Logic to the "Book List" Template

Open root/src/books/list.tt2 in your editor and add the following lines to the bottom of the file:

...
<p>Hello [% c.user.username %], you have the following roles:</p>

<ul>
  [% # Dump list of roles -%]
  [% FOR role = c.user.roles %]<li>[% role %]</li>[% END %]
</ul>

<p>
[% # Add some simple role-specific logic to template %]
[% # Use $c->check_user_roles() to check authz -%]
[% IF c.check_user_roles('user') %]
  [% # Give normal users a link for 'logout' %]
  <a href="[% c.uri_for('/logout') %]">User Logout</a>
[% END %]

[% # Can also use $c->user->check_roles() to check authz -%]
[% IF c.check_user_roles('admin') %]
  [% # Give admin users a link for 'create' %]
  <a href="[% c.uri_for(c.controller.action_for('form_create')) %]">Admin Create</a>
[% END %]
</p>

This code displays a different combination of links depending on the roles assigned to the user.

Limit `Books::add` to `admin` Users

IF statements in TT templates simply control the output that is sent to the user's browser; it provides no real enforcement (if users know or guess the appropriate URLs, they are still perfectly free to hit any action within your application). We need to enhance the controller logic to wrap restricted actions with role-validation logic.

For example, we might want to restrict the "formless create" action to admin-level users by editing lib/MyApp/Controller/Books.pm and updating url_create to match the following code:

=head2 url_create

Create a book with the supplied title and rating,
with manual authorization

=cut

sub url_create :Chained('base') :PathPart('url_create') :Args(3) {
    # In addition to self & context, get the title, rating & author_id args
    # from the URL.  Note that Catalyst automatically puts extra information
    # after the "/<controller_name>/<action_name/" into @_
    my ($self, $c, $title, $rating, $author_id) = @_;

    # Check the user's roles
    if ($c->check_user_roles('admin')) {
        # Call create() on the book model object. Pass the table
        # columns/field values we want to set as hash values
        my $book = $c->model('DB::Books')->create({
                title   => $title,
                rating  => $rating
            });

        # Add a record to the join table for this book, mapping to
        # appropriate author
        $book->add_to_book_authors({author_id => $author_id});
        # Note: Above is a shortcut for this:
        # $book->create_related('book_authors', {author_id => $author_id});

        # Assign the Book object to the stash for display in the view
        $c->stash->{book} = $book;

        # This is a hack to disable XSUB processing in Data::Dumper
        # (it's used in the view).  This is a work-around for a bug in
        # the interaction of some versions or Perl, Data::Dumper & DBIC.
        # You won't need this if you aren't using Data::Dumper (or if
        # you are running DBIC 0.06001 or greater), but adding it doesn't
        # hurt anything either.
        $Data::Dumper::Useperl = 1;

        # Set the TT template to use
        $c->stash->{template} = 'books/create_done.tt2';
    } else {
        # Provide very simple feedback to the user.
        $c->response->body('Unauthorized!');
    }
}

To add authorization, we simply wrap the main code of this method in an if statement that calls check_user_roles. If the user does not have the appropriate permissions, they receive an "Unauthorized!" message. Note that we intentionally chose to display the message this way to demonstrate that TT templates will not be used if the response body has already been set. In reality you would probably want to use a technique that maintains the visual continuity of your template layout (for example, using the "status" or "error" message feature added in Part 3 or detach to an action that shows an "unauthorized" page).

TIP: If you want to keep your existing url_create method, you can create a new copy and comment out the original by making it look like a Pod comment. For example, put something like =begin before sub add : Local { and =end after the closing }.

Try Out Authentication And Authorization

Press Ctrl-C to kill the previous server instance (if it's still running) and restart it:

$ script/myapp_server.pl

Now trying going to http://localhost:3000/books/list and you should be taken to the login page (you might have to Shift+Reload or Ctrl+Reload your browser and/or click the "User Logout" link on the book list page). Try logging in with both test01 and test02 (both use a password of mypass) and notice how the roles information updates at the bottom of the "Book List" page. Also try the "User Logout" link on the book list page.

Now the "url_create" URL will work if you are already logged in as user test01, but receive an authorization failure if you are logged in as test02. Try:

http://localhost:3000/books/url_create/test/1/6

while logged in as each user. Use one of the "logout" links (or go to http://localhost:3000/logout in your browser directly) when you are done.

ENABLE MODEL-BASED AUTHORIZATION

Hopefully it's fairly obvious that adding detailed permission checking logic to our controllers and view templates isn't a very clean or scalable way to build role-based permissions into out application. As with many other aspects of MVC web development, the goal is to have your controllers and views be an "thin" as possible, with all of the "fancy business logic" built into your model.

For example, let's add a method to our Books.pm Result Class to check if a user is allowed to delete a book. Open lib/MyApp/Schema/Result/Books.pm and add the following method (be sure to add it below the "DO NOT MODIFY ..." line):

=head2 delete_allowed_by

Can the specified user delete the current book?

=cut

sub delete_allowed_by {
    my ($self, $user) = @_;
    
    # Only allow delete if user has 'admin' role
    return $user->has_role('admin');
}

Here we call a has_role method on our user object, so we should add this method to our Result Class. Open lib/MyApp/Schema/Result/Users.pm and add this near the top:

use Perl6::Junction qw/any/;

And then add the following method below the "DO NOT MODIFY ..." line:

=head 2 has_role

Check if a user has the specified role

=cut

sub has_role {
    my ($self, $role) = @_;

    # Does this user posses the required role?
    return any(map { $_->role } $self->roles) eq $role;
}

Now we need to add some enforcement inside our controller. Open lib/MyApp/Controller/Books.pm and update the delete method to match the following code:

=head2 delete

Delete a book

=cut

sub delete :Chained('object') :PathPart('delete') :Args(0) {
    my ($self, $c) = @_;

    # Check permissions
    $c->detach('/error_noperms')
        unless $c->stash->{object}->delete_allowed_by($c->user->get_object);

    # Use the book object saved by 'object' and delete it along
    # with related 'book_authors' entries
    $c->stash->{object}->delete;

    # Use 'flash' to save information across requests until it's read
    $c->flash->{status_msg} = "Book deleted";

    # Redirect the user back to the list page
    $c->response->redirect($c->uri_for($self->action_for('list')));
}

Here, we detach to an error page if the user is lacking the appropriate permissions. For this to work, we need to make arrangements for the '/error_noperms' action to work. Open lib/MyApp/Controller/Root.pm and add this method:

=head2 error_noperms

Permissions error screen

=cut
    
sub error_noperms :Chained('/') :PathPath('error_noperms') :Args(0) {
    my ($self, $c) = @_;

    $c->stash->{template} = 'error_noperms.tt2';
}

And also add the template file by putting the following text into root/src/error_noperms.tt2:

<span class="error">Permission Denied</span>

Then run the Catalyst development server script:

$ script/myapp_server.pl

http://localhost:3000/books/url_create/Test/1/4

Then, while still logged in as test01, click the "Delete" link next to one of these books. The book should be removed and you should see the usual green "Book deleted" message. Next, click the "User Logout" link and log back in as test02. Now try deleting one of the books. You should be taken to the red "Permission Denied" message on our error page.

Use one of the 'Logout' links (or go to the http://localhost:3000/logout URL directly) when you are done.

AUTHOR

Kennedy Clark, hkclark@gmail.com

Please report any errors, issues or suggestions to the author. The most recent version of the Catalyst Tutorial can be found at http://dev.catalyst.perl.org/repos/Catalyst/Catalyst-Manual/5.70/trunk/lib/Catalyst/Manual/Tutorial/.

To install Catalyst::Manual, copy and paste the appropriate command in to your terminal.

cpanm

cpanm Catalyst::Manual

CPAN shell

perl -MCPAN -e shell
install Catalyst::Manual

For more information on module installation, please visit the detailed CPAN module installation guide.

	Global
`s`	Focus search bar
`?`	Bring up this help dialog

	GitHub
`g` `p`	Go to pull requests
`g` `i`	go to github issues (only if github is preferred repository)

	POD
`g` `a`	Go to author
`g` `c`	Go to changes
`g` `i`	Go to issues
`g` `d`	Go to dist
`g` `r`	Go to repository/SCM
`g` `s`	Go to source
`g` `b`	Go to file browse

	Search terms
module: (e.g. module:Plugin)
distribution: (e.g. distribution:Dancer auth)
author: (e.g. author:SONGMU Redis)
version: (e.g. version:1.00)