NAME

ZMQ::LibZMQ3 - A libzmq 3.x wrapper for Perl

SYNOPSIS

use ZMQ::LibZMQ3;
use ZMQ::Constants; # separate module

my $ctxt = zmq_init($threads);
my $rv   = zmq_term($ctxt);

my $msg  = zmq_msg_init();
my $msg  = zmq_msg_init_size( $size );
my $msg  = zmq_msg_init_data( $data );
my $rv   = zmq_msg_close( $msg );
my $rv   = zmq_msg_move( $dest, $src );
my $rv   = zmq_msg_copy( $dest, $src );
my $data = zmq_msg_data( $msg );
my $size = zmq_msg_size( $msg);

my $sock = zmq_socket( $ctxt, $type );
my $rv   = zmq_close( $sock );
my $rv   = zmq_setsockopt( $socket, $option, $value );
my $val  = zmq_getsockopt( $socket, $option );
my $rv   = zmq_bind( $sock, $addr );
my $rv   = zmq_send( $sock, $buffer, $length, $flags );
my $msg  = zmq_sendmsg( $sock, $msg, $flags );
my $rv   = zmq_recv( $sock, $buffer, $length, $flags );
my $msg  = zmq_recvmsg( $sock, $flags );

INSTALLATION

If you have libzmq registered with pkg-config:

perl Makefile.PL
make 
make test
make install

If you don't have pkg-config, and libzmq is installed under /usr/local/libzmq:

ZMQ_HOME=/usr/local/libzmq \
    perl Makefile.PL
make
make test
make install

If you want to customize include directories and such:

ZMQ_INCLUDES=/path/to/libzmq/include \
ZMQ_LIBS=/path/to/libzmq/lib \
ZMQ_H=/path/to/libzmq/include/zmq.h \
    perl Makefile.PL
make
make test
make install

If you want to compile with debugging on:

perl Makefile.PL -g

DESCRIPTION

The ZMQ::LibZMQ3 module is a wrapper of the 0MQ message passing library for Perl.

Before you start using this module, please make sure you have read and understood the zguide.

http://zguide.zeromq.org/page:all

For specifics on each function, please refer to their documentation for the definitive explanation of each.

http://api.zeromq.org/

This module is merely a thin wrapper around the C API: You need to understand how the C API works in order to properly use this module.

Note that this is a wrapper for libzmq 3.x. For 2.x, you need to check ZMQ::LibZMQ2

BASIC USAGE

Please make sure you already have ZMQ::Constants module. If you installed ZMQ::LibZMQ3 from CPAN via cpan/cpanm, it should have already been installed for you. All socket types and other flags are declared in this module.

To start using ZMQ::LibZMQ3, you need to create a context object, then as many ZMQ::LibZMQ3::Socket objects as you need:

my $ctxt = zmq_init;
my $socket = zmq_socket( $ctxt, ... options );

You need to call zmq_bind() or zmq_connect() on the socket, depending on your usage. For example on a typical server-client model you would write on the server side:

zmq_bind( $socket, "tcp://127.0.0.1:9999" );

and on the client side:

zmq_connect( $socket, "tcp://127.0.0.1:9999" );

The underlying zeromq library offers TCP, multicast, in-process, and ipc connection patterns. Read the zeromq manual for more details on other ways to setup the socket.

When sending data, you can either pass a ZMQ::LibZMQ3::Message object or a Perl string.

# the following two send() calls are equivalent
my $msg = zmq_msg_init_data( "a simple message" );
zmq_sendmsg( $socket, $msg );

zmq_sendmsg( $socket, "a simple message" );

In most cases using ZMQ::LibZMQ3::Message is redundant, so you will most likely use the string version.

To receive, simply call zmq_recvmsg() on the socket

my $msg = zmq_recvmsg( $socket );

The received message is an instance of ZMQ::LibZMQ3::Message object, and you can access the content held in the message via the zmq_msg_data() method:

my $data = zmq_msg_data( $msg );

WHEN IN DOUBT

0MQ is a relatively large framework, and to use it you need to be comfortable with a lot of concepts. If you think this module is not behaving like you expect it to, please read the documents for the C API

ASYNCHRONOUS I/O WITH ZEROMQ

By default 0MQ comes with its own zmq_poll() mechanism that can handle non-blocking sockets. You can use this by calling zmq_poll with a list of hashrefs:

zmq_poll([
    {
        fd => fileno(STDOUT),
        events => ZMQ_POLLOUT,
        callback => \&callback,
    },
    {
        socket => $zmq_socket,
        events => ZMQ_POLLIN,
        callback => \&callback
    },
], $timeout );

Unfortunately this custom polling scheme doesn't play too well with AnyEvent.

Fortunately you can use getsockopt to retrieve the underlying file descriptor, so use that to integrate ZMQ::LibZMQ3 and AnyEvent:

my $socket = zmq_socket( $ctxt, ZMQ_REP );
my $fh = zmq_getsockopt( $socket, ZMQ_FD );
my $w; $w = AE::io $fh, 0, sub {
    while ( my $msg = zmq_recv( $socket, ZMQ_RCVMORE ) ) {
        # do something with $msg;
    }
    undef $w;
};

NOTES ON MULTI-PROCESS and MULTI-THREADED USAGE

0MQ works on both multi-process and multi-threaded use cases, but you need to be careful about sharing ZMQ::LibZMQ3 objects.

For multi-process environments, you should not be sharing the context object. Create separate contexts for each process, and therefore you shouldn't be sharing the socket objects either.

For multi-thread environments, you can share the same context object. However you cannot share sockets. Note that while the Perl Socket objects survive between threads, their underlying C structures do not, and you will get an error if you try to use them between sockets.

FUNCTIONS

ZMQ::LibZMQ3 attempts to stick to the libzmq interface as much as possible. Unless there is a structural problem (say, an underlying pointer that the Perl binding expects was missing), no function should throw an exception.

Return values should resemble that of libzmq, except for when new data is allocated and returned to the user - That includes things like zmq_init(), zmq_socket(), zmq_msg_data(), etc.

Where applicable, $! should be updated to match the value set by libzmq, so you should be able to do:

my $cxt = zmq_init();
if (! $cxt) {
    die "zmq_init() failed with $!";
}

$errno = zmq_errno()

Returns the value of errno variable for the calling thread. You normally should not need to use this function. See the man page for zmq_errno() provided by libzmq.

$string = zmq_strerror( $errno )

Returns the string representation of $errno. Use this to stringify errors that libzmq provides.

$cxt = zmq_init( $threads )

Creates a new context object. $threads argument is optional. Context objects can be reused across threads.

Returns undef upon error, and sets $!.

Note: Deprecated in libzmq, but the Perl binding will silently fallback to using zmq_ctx_new(), if available.

$cxt = zmq_ctx_new( $threads );

Creates a new context object. $threads argument is optional. Context objects can be reused across threads.

Returns undef upon error, and sets $!.

Note: may not be available depending on your libzmq version.

$rv = zmq_ctx_get( $cxt, $option )

Gets the value for the given option.

Returns -1 status upon failure, and sets $!

Note: may not be available depending on your libzmq version.

$rv = zmq_ctx_set( $cxt, $option, $value )

Sets the value for the given option.

Returns a non-zero status upon failure, and sets $!.

Note: may not be available depending on your libzmq version.

$rv = zmq_term( $cxt )

Terminates the context. Be careful, as it might hang if you have pending socket operations.

Returns a non-zero status upon failure, and sets $!.

Note: Deprecated in libzmq, but the Perl binding will silently fallback to using zmq_ctx_destroy(), if available.

$rv = zmq_ctx_destroy( $cxt )

Terminates the context. Be careful, as it might hang if you have pending socket operations.

Returns a non-zero status upon failure, and sets $!.

Note: may not be available depending on your libzmq version.

$socket = zmq_socket( $cxt, $socket_type )

Creates a new socket object. $socket_types are constants declared in ZMQ::Constants. Sockets cannot be reused across threads.

Returns undef upon error, and sets $!.

$rv = zmq_bind( $sock, $address )

Binds the socket to listen to specified $address.

Returns a non-zero status upon failure, and sets $!

$rv = zmq_unbind( $sock, $address )

Stops listening on this endpoint.

Returns a non-zero status upon failure, and sets $!

Note: may not be available depending on your libzmq version.

$rv = zmq_connect( $sock, $address )

Connects the socket to the specified $address.

Returns a non-zero status upon failure, and sets $!

$rv = zmq_disconnect( $sock, $address )

Disconnects the socket from the specified $address.

Returns a non-zero status upon failure, and sets $!

Note: may not be available depending on your libzmq version.

$rv = zmq_close( $sock )

Closes the socket explicitly.

Returns a non-zero status upon failure, and sets $!.

$value = zmq_getsockopt( $socket, $option )

Gets the value of the specified option.

If the particular version of ZMQ::LibZMQ3 does not implement the named socket option, an exception will be thrown:

/* barfs, because we don't know what type this new option is */
zmq_getsockopt( $socket, ZMQ_NEW_SHINY_OPTION );

In this case you can either use ZMQ::Constants, or you can use one of the utility functions that ZMQ::LibZMQ3 provides.

Using ZMQ::Constants

ZMQ::LibZMQ3 internally refers to ZMQ::Constants to learn about the type of a socket option. You can easily add new constants to this map:

use ZMQ::Constants;
ZMQ::Constants::add_sockopt_type( "int" => ZMQ_NEW_SHINY_OPTION );

# Then elsewhere...
my $value = zmq_getsockopt( $socket, ZMQ_NEW_SHINY_OPTION );

Using utilities in ZMQ::LibZMQ3

/* say you know that the value is an int, int64, uint64, or char *
   by reading the zmq docs */
$int    = zmq_getsockopt_int( $socket, ZMQ_NEW_SHINY_OPTION );
$int64  = zmq_getsockopt_int64( $socket, ZMQ_NEW_SHINY_OPTION );
$uint64 = zmq_getsockopt_uint64( $socket, ZMQ_NEW_SHINY_OPTION );
$string = zmq_getsockopt_string( $socket, ZMQ_NEW_SHINY_OPTION );

$status = zmq_setsockopt( $socket, $option, $value )

Sets the value of the specified option. Returns the status.

See zmq_getsockopt() if you have problems with ZMQ::LibZMQ3 not knowing the type of the option.

$bytes = zmq_send($sock, $buffer, $size, $flags)

Queues $size bytes from $buffer to be sent from the socket. Argument $flags may be omitted. If $size is -1, then the size of the buffer calculated via SvPV() will be used.

Returns the number of bytes sent on success (which should be exact $size)

Returns -1 upon failure, and sets $!.

$rv = zmq_sendmsg($sock, $message, $flags)

Queues $message to be sent via $sock. Argument $flags may be omitted.

If $message is a non-ref, creates a new ZMQ::LibZMQ3::Message object via zmq_msg_init_data(), and uses that to pass to the underlying C layer..

Returns the number of bytes sent on success (which should be exact $size)

Returns -1 upon failure, and sets $!.

Note: Deprecated in favor of zmq_msg_send(), and may not be available depending on your libzmq version.

$rv = zmq_msg_send($message, $sock, $flags)

Queues $message to be sent via $sock. Argument $flags may be omitted.

If $message is a non-ref, creates a new ZMQ::LibZMQ3::Message object via zmq_msg_init_data(), and uses that to pass to the underlying C layer..

Returns the number of bytes sent on success (which should be exact $size)

Returns -1 upon failure, and sets $!.

Note: may not be available depending on your libzmq version.

$rv = zmq_recv($sock, $buffer, $len, $flags)

Receives a new message from $sock, and store the message payload in $buffer, up to $len bytes. Argument $flags may be omitted.

Returns the number of bytes in the original message, which may exceed $len (if you have $rv > $len, then the message was truncated).

Returns -1 upon failure, and sets $!.

$message = zmq_recvmsg($sock, $flags)

Receives a new message from $sock. Argument $flags may be omitted. Returns the message object.

Returns undef upon failure, and sets $!.

Note: Although this function is marked as deprecated in libzmq3, it will stay in the Perl binding as the official short-circuit version of zmq_msg_recv(), so that you don't have to create a message object every time.

$rv = zmq_msg_recv($msg, $sock, $flags)

Receives a new message from $sock, and writes the new content to $msg. Argument $flags may be omitted.

Returns the number of bytes in the message if successful.

Returns -1 upon failure, and sets $!.

Other than the fact that libzmq has deprecated zmq_recvmsg(), this construct is useful if you don't want to allocate a message struct for every recv call:

my $msg = zmq_msg_init();
while (1) {
    my $rv = zmq_msg_recv($msg, $sock, $flags);
    ...
}

Note: may not be available depending on your libzmq version

$msg = zmq_msg_init()

Creates a new message object.

Returns undef upon failure, and sets $!.

$msg = zmq_msg_init_data($string)

Creates a new message object, and sets the message payload to the string in $string.

Returns undef upon failure, and sets $!.

$msg = zmq_msg_init_size($size)

Creates a new message object, allocating $size bytes. This call isn't so useful from within Perl

Returns undef upon failure, and sets $!.

$string = zmq_msg_data( $msg )

Returns the payload contained in $msg

$size = zmq_msg_size( $msg )

Returns the size of payload contained in $msg

zmq_msg_copy( $dst, $src )

Copies contents of $src to $dst.

Returns a non-zero status upon failure, and sets $!.

zmq_msg_move( $dst, $src )

Moves contents of $src to $dst

Returns a non-zero status upon failure, and sets $!.

$rv = zmq_msg_close( $msg )

Closes, cleans up the message.

Returns a non-zero status upon failure, and sets $!.

$rv = zmq_poll( \@pollitems, $timeout )

@pollitems are list of hash references containing the following elements:

fd or socket: One of either fd or socket key must exist. fd should contain a UNIX file descriptor. socket should contain a ZMQ::LibZMQ3::Socket socket object.
events: A bit mask containing ZMQ_POLLOUT, ZMQ_POLLIN, ZMQ_POLLERR or combination there of.
callback: A subroutine reference, which will be called without arguments when the socket or descriptor is available.

In scalar context, returns the return value of zmq_poll() in the C layer, and sets $!.

my $rv = zmq_poll( .... ); # do scalar(zmq_poll(...)) if you're nuerotic
if ( $rv == -1 ) {
    warn "zmq_poll failed: $!";
}

In list context, return a list containing as many booleans as there are elements in @pollitems. These booleans indicate whether the socket in question has fired the callback.

my @pollitems = (...);
my @fired     = zmq_poll( @pollitems ... );
for my $i ( 0 .. $#pollitems ) {
    my $fired = $fired[$i];
    if ( $fired ) {
        my $item = $pollitems[$i];
        ...
    }
}

zmq_version()

Returns the version of the underlying zeromq library that is being linked. In scalar context, returns a dotted version string. In list context, returns a 3-element list of the version numbers:

my $version_string = ZMQ::LibZMQ3::zmq_version();
my ($major, $minor, $patch) = ZMQ::LibZMQ3::zmq_version();

zmq_device($type, $sock1, $sock2)

Creates a new "device". See zmq_device for details. zmq_device() will only return if/when the current context is closed. Therefore, the return value is always -1, and $! is always ETERM

Note: may not be available depending on your libzmq version.

zmq_proxy($frontend_sock, $backend_sock, $capture_sock)

WARNING: EXPERIMENTAL. Use at your own risk.

Start a proxy in the current thread, which connects the frontend socket to a backend socket. The capture sock is optional, and is by default undef.

Note: may not be available depending on your libzmq version.

$rv = zmq_socket_monitor($socket, $addr, events)

Note: may not be available depending on your libzmq version.

FUNCTIONS PROVIDED BY ZMQ::LIBZMQ3

These functions are provided by ZMQ::LibZMQ3 to make some operations easier in the Perl binding. They are not part of the official libzmq interface.

$value = zmq_getsockopt_int( $sock, $option )

$value = zmq_getsockopt_int64( $sock, $option )

$value = zmq_getsockopt_string( $sock, $option )

$value = zmq_getsockopt_uint64( $sock, $option )

$rv = zmq_setsockopt_int( $sock, $option, $value );

$rv = zmq_setsockopt_int64( $sock, $option, $value );

$rv = zmq_setsockopt_string( $sock, $option, $value );

$rv = zmq_setsockopt_uint64( $sock, $option, $value );

DEBUGGING XS

If you see segmentation faults, and such, you need to figure out where the error is occurring in order for the maintainers to figure out what happened. Here's a very very brief explanation of steps involved.

First, make sure to compile ZMQ::LibZMQ3 with debugging on by specifying -g:

perl Makefile.PL -g
make

Then fire gdb:

gdb perl
(gdb) R -Mblib /path/to/your/script.pl

When you see the crash, get a backtrace:

(gdb) bt

CAVEATS

This is an early release. Proceed with caution, please report (or better yet: fix) bugs you encounter.

This module has been tested against zeromq 3.2.2. Semantics of this module rely heavily on the underlying zeromq version. Make sure you know which version of zeromq you're working with.

As of 1.04 some new constants have been added, but they are not really meant to be used by consumers of this module. If you find yourself looking at these, please let us know why you need to use it -- we'll see if we can find a workaround, or make these constants public.

AUTHOR

Daisuke Maki <daisuke@endeworks.jp>

Steffen Mueller, <smueller@cpan.org>

COPYRIGHT AND LICENSE

The ZMQ::LibZMQ3 module is

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself, either Perl version 5.8.0 or, at your option, any later version of Perl 5 you may have available.

To install ZMQ::LibZMQ3, copy and paste the appropriate command in to your terminal.

cpanm

cpanm ZMQ::LibZMQ3

CPAN shell

perl -MCPAN -e shell
install ZMQ::LibZMQ3

For more information on module installation, please visit the detailed CPAN module installation guide.

	Global
`s`	Focus search bar
`?`	Bring up this help dialog

	GitHub
`g` `p`	Go to pull requests
`g` `i`	go to github issues (only if github is preferred repository)

	POD
`g` `a`	Go to author
`g` `c`	Go to changes
`g` `i`	Go to issues
`g` `d`	Go to dist
`g` `r`	Go to repository/SCM
`g` `s`	Go to source
`g` `b`	Go to file browse

	Search terms
module: (e.g. module:Plugin)
distribution: (e.g. distribution:Dancer auth)
author: (e.g. author:SONGMU Redis)
version: (e.g. version:1.00)

NAME

SYNOPSIS

INSTALLATION

DESCRIPTION

BASIC USAGE

WHEN IN DOUBT

ASYNCHRONOUS I/O WITH ZEROMQ

NOTES ON MULTI-PROCESS and MULTI-THREADED USAGE

FUNCTIONS

$errno = zmq_errno()

$string = zmq_strerror( $errno )

$cxt = zmq_init( $threads )

$cxt = zmq_ctx_new( $threads );

$rv = zmq_ctx_get( $cxt, $option )

$rv = zmq_ctx_set( $cxt, $option, $value )

$rv = zmq_term( $cxt )

$rv = zmq_ctx_destroy( $cxt )

$socket = zmq_socket( $cxt, $socket_type )

$rv = zmq_bind( $sock, $address )

$rv = zmq_unbind( $sock, $address )

$rv = zmq_connect( $sock, $address )

$rv = zmq_disconnect( $sock, $address )

$rv = zmq_close( $sock )

$value = zmq_getsockopt( $socket, $option )

$status = zmq_setsockopt( $socket, $option, $value )

$bytes = zmq_send($sock, $buffer, $size, $flags)

$rv = zmq_sendmsg($sock, $message, $flags)

$rv = zmq_msg_send($message, $sock, $flags)

$rv = zmq_recv($sock, $buffer, $len, $flags)

$message = zmq_recvmsg($sock, $flags)

$rv = zmq_msg_recv($msg, $sock, $flags)

$msg = zmq_msg_init()

$msg = zmq_msg_init_data($string)

$msg = zmq_msg_init_size($size)

$string = zmq_msg_data( $msg )

$size = zmq_msg_size( $msg )

zmq_msg_copy( $dst, $src )

zmq_msg_move( $dst, $src )

$rv = zmq_msg_close( $msg )

$rv = zmq_poll( \@pollitems, $timeout )

zmq_version()

zmq_device($type, $sock1, $sock2)

zmq_proxy($frontend_sock, $backend_sock, $capture_sock)

$rv = zmq_socket_monitor($socket, $addr, events)

FUNCTIONS PROVIDED BY ZMQ::LIBZMQ3

$value = zmq_getsockopt_int( $sock, $option )

$value = zmq_getsockopt_int64( $sock, $option )

$value = zmq_getsockopt_string( $sock, $option )

$value = zmq_getsockopt_uint64( $sock, $option )

$rv = zmq_setsockopt_int( $sock, $option, $value );

$rv = zmq_setsockopt_int64( $sock, $option, $value );

$rv = zmq_setsockopt_string( $sock, $option, $value );

$rv = zmq_setsockopt_uint64( $sock, $option, $value );

DEBUGGING XS

CAVEATS

SEE ALSO

AUTHOR

COPYRIGHT AND LICENSE

Module Install Instructions