NAME

Class::MakeMethods::Composite::Hash - Composite hash methods

SYNOPSIS

package MyObject;
use Class::MakeMethods::Composite::Hash (
  new => 'new',
  scalar => [ 'foo', 'bar' ],
  array => 'my_list',
  hash => 'my_index',
);
...

my $obj = MyObject->new( foo => 'Foozle' );
print $obj->foo();

$obj->bar('Barbados'); 
print $obj->bar();

$obj->my_list(0 => 'Foozle', 1 => 'Bang!');
print $obj->my_list(1);

$obj->my_index('broccoli' => 'Blah!', 'foo' => 'Fiddle');
print $obj->my_index('foo');

DESCRIPTION

The Composite::Hash suclass of MakeMethods provides a basic constructor and accessors for blessed-hash object instances.

Class::MakeMethods Calling Interface

When you use this package, the method declarations you provide as arguments cause subroutines to be generated and installed in your module.

You can also omit the arguments to use and instead make methods at runtime by passing the declarations to a subsequent call to make().

You may include any number of declarations in each call to use or make(). If methods with the same name already exist, earlier calls to use or make() win over later ones, but within each call, later declarations superceed earlier ones.

You can install methods in a different package by passing -TargetClass => package as your first arguments to use or make.

See Class::MakeMethods for more details.

Class::MakeMethods::Basic Declaration Syntax

The following types of Basic declarations are supported:

generator_type => "method_name"
generator_type => "name_1 name_2..."
generator_type => [ "name_1", "name_2", ...]

See the "METHOD GENERATOR TYPES" section below for a list of the supported values of generator_type.

For each method name you provide, a subroutine of the indicated type will be generated and installed under that name in your module.

Method names should start with a letter, followed by zero or more letters, numbers, or underscores.

Class::MakeMethods::Composite Declaration Syntax

The Composite syntax also provides several ways to optionally associate a hash of additional parameters with a given method name.

generator_type => [ "name_1" => { param=>value... }, ... ]

A hash of parameters to use just for this method name.

(Note: to prevent confusion with self-contained definition hashes, described below, parameter hashes following a method name must not contain the key 'name'.)
generator_type => [ [ "name_1", "name_2", ... ] => { param=>value... } ]

Each of these method names gets a copy of the same set of parameters.
generator_type => [ { "name"=>"name_1", param=>value... }, ... ]

By including the reserved parameter name, you create a self-contained declaration with that name and any associated hash values.

Basic declarations, as described above, are given an empty parameter hash.

METHOD GENERATOR TYPES

new - Constructor

For each method name passed, returns a subroutine with the following characteristics:

Has a reference to a sample item to copy. This defaults to a reference to an empty hash, but you may override this with the 'defaults' => hash_ref method parameter.
If called as a class method, makes a new hash and blesses it into that class.
If called on a hash-based instance, makes a copy of it and blesses the copy into the same class as the original instance.
If passed a list of key-value pairs, appends them to the new hash. These arguments override any copied values, and later arguments with the same name will override earlier ones.
Returns the new instance.

Sample declaration and usage:

package MyObject;
use Class::MakeMethods::Composite::Hash (
  new => 'new',
);
...

# Bare constructor
my $empty = MyObject->new();

# Constructor with initial values
my $obj = MyObject->new( foo => 'Foozle', bar => 'Barbados' );

# Copy with overriding value
my $copy = $obj->new( bar => 'Bob' );

new --with_values - Constructor

For each method name passed, returns a subroutine with the following characteristics:

May be called as a class method, or (equivalently) on any existing object of that class.
Creates a hash, blesses it into the class, and returns the new instance.
If no arguments are provided, the returned hash will be empty. If passed a single hash-ref argument, copies its contents into the new hash. If called with multiple arguments, treats them as key-value pairs, and copies them into the new hash. (Note that this is a "shallow" copy, not a "deep" clone.)

scalar - Instance Accessor

For each method name passed, uses a closure to generate a subroutine with the following characteristics:

Must be called on a hash-based instance.
Has a specific hash key to use to access the related value for each instance. This defaults to the method name, but you may override this with the 'hash_key' = string> method parameter.
If called without any arguments returns the current value.
If called with an argument, stores that as the value, and returns it.
If called with multiple arguments, stores a reference to a new array with those arguments as contents, and returns that array reference.

Sample declaration and usage:

package MyObject;
use Class::MakeMethods::Composite::Hash (
  scalar => 'foo',
);
...

# Store value
$obj->foo('Foozle');

# Retrieve value
print $obj->foo;

array - Instance Ref Accessor

For each method name passed, uses a closure to generate a subroutine with the following characteristics:

Must be called on a hash-based instance.
Has a specific hash key to use to access the related value for each instance. This defaults to the method name, but you may override this with the 'hash_key' = string> method parameter.
The value for each instance will be a reference to an array (or undef).
If called without any arguments, returns the current array-ref value (or undef).
If called with a single non-ref argument, uses that argument as an index to retrieve from the referenced array, and returns that value (or undef).
If called with a single array ref argument, uses that list to return a slice of the referenced array.
If called with a list of argument pairs, each with a non-ref index and an associated value, stores the value at the given index in the referenced array. If the instance's value was previously undefined, a new array is autovivified. The current value in each position will be overwritten, and later arguments with the same index will override earlier ones. Returns the current array-ref value.
If called with a list of argument pairs, each with the first item being a reference to an array of up to two numbers, loops over each pair and uses those numbers to splice the value array.

The first controlling number is the position at which the splice will begin. Zero will start before the first item in the list. Negative numbers count backwards from the end of the array.

The second number is the number of items to be removed from the list. If it is omitted, or undefined, or zero, no items are removed. If it is a positive integer, that many items will be returned.

If both numbers are omitted, or are both undefined, they default to containing the entire value array.

If the second argument is undef, no values will be inserted; if it is a non-reference value, that one value will be inserted; if it is an array-ref, its values will be copied.

The method returns the items that removed from the array, if any.

Sample declaration and usage:

package MyObject;
use Class::MakeMethods::Composite::Hash (
  array => 'bar',
);
...

# Clear and set contents of list
print $obj->bar([ 'Spume', 'Frost' ] );  

# Set values by position
$obj->bar(0 => 'Foozle', 1 => 'Bang!');

# Positions may be overwritten, and in any order
$obj->bar(2 => 'And Mash', 1 => 'Blah!');

# Retrieve value by position
print $obj->bar(1);

# Direct access to referenced array
print scalar @{ $obj->bar() };

There are also calling conventions for slice and splice operations:

# Retrieve slice of values by position
print join(', ', $obj->bar( undef, [0, 2] ) );

# Insert an item at position in the array
$obj->bar([3], 'Potatoes' );  

# Remove 1 item from position 3 in the array
$obj->bar([3, 1], undef );  

# Set a new value at position 2, and return the old value 
print $obj->bar([2, 1], 'Froth' );

hash - Instance Ref Accessor

For each method name passed, uses a closure to generate a subroutine with the following characteristics:

Must be called on a hash-based instance.
Has a specific hash key to use to access the related value for each instance. This defaults to the method name, but you may override this with the 'hash_key' = string> method parameter.
The value for each instance will be a reference to a hash (or undef).
If called without any arguments, returns the contents of the hash in list context, or a hash reference in scalar context (or undef).
If called with one non-ref argument, uses that argument as an index to retrieve from the referenced hash, and returns that value (or undef).
If called with one array-ref argument, uses the contents of that array to retrieve a slice of the referenced hash.
If called with one hash-ref argument, sets the contents of the referenced hash to match that provided.
If called with a list of key-value pairs, stores the value under the given key in the referenced hash. If the instance's value was previously undefined, a new hash is autovivified. The current value under each key will be overwritten, and later arguments with the same key will override earlier ones. Returns the contents of the hash in list context, or a hash reference in scalar context.

Sample declaration and usage:

package MyObject;
use Class::MakeMethods::Composite::Hash (
  hash => 'baz',
);
...

# Set values by key
$obj->baz('foo' => 'Foozle', 'bar' => 'Bang!');

# Values may be overwritten, and in any order
$obj->baz('broccoli' => 'Blah!', 'foo' => 'Fiddle');

# Retrieve value by key
print $obj->baz('foo');

# Retrive slice of values by position
print join(', ', $obj->baz( ['foo', 'bar'] ) );

# Direct access to referenced hash
print keys %{ $obj->baz() };

# Reset the hash contents to empty
@{ $obj->baz() } = ();

object - Instance Ref Accessor

For each method name passed, uses a closure to generate a subroutine with the following characteristics:

Must be called on a hash-based instance.
Has a specific hash key to use to access the related value for each instance. This defaults to the method name, but you may override this with the 'hash_key' = string> method parameter.
The value for each instance will be a reference to an object (or undef).
If called without any arguments returns the current value.
If called with an argument, stores that as the value, and returns it,

Sample declaration and usage:

package MyObject;
use Class::MakeMethods::Composite::Hash (
  object => 'foo',
);
...

# Store value
$obj->foo( Foozle->new() );

# Retrieve value
print $obj->foo;

	Global
`s`	Focus search bar
`?`	Bring up this help dialog

	GitHub
`g` `p`	Go to pull requests
`g` `i`	go to github issues (only if github is preferred repository)

	POD
`g` `a`	Go to author
`g` `c`	Go to changes
`g` `i`	Go to issues
`g` `d`	Go to dist
`g` `r`	Go to repository/SCM
`g` `s`	Go to source
`g` `b`	Go to file browse

	Search terms
module: (e.g. module:Plugin)
distribution: (e.g. distribution:Dancer auth)
author: (e.g. author:SONGMU Redis)
version: (e.g. version:1.00)

NAME

SYNOPSIS

DESCRIPTION

Class::MakeMethods Calling Interface

Class::MakeMethods::Basic Declaration Syntax

Class::MakeMethods::Composite Declaration Syntax

METHOD GENERATOR TYPES

new - Constructor

new --with_values - Constructor

scalar - Instance Accessor

array - Instance Ref Accessor

hash - Instance Ref Accessor

object - Instance Ref Accessor

SEE ALSO

Module Install Instructions