NAME

Moose - A complete modern object system for Perl 5

SYNOPSIS

package Point;
use Moose; # automatically turns on strict and warnings

has 'x' => (is => 'rw', isa => 'Int');
has 'y' => (is => 'rw', isa => 'Int');

sub clear {
    my $self = shift;
    $self->x(0);
    $self->y(0);
}

package Point3D;
use Moose;

extends 'Point';

has 'z' => (is => 'rw', isa => 'Int');

after 'clear' => sub {
    my $self = shift;
    $self->z(0);
};

DESCRIPTION

Moose is an extension of the Perl 5 object system.

Another object system!?!?

Yes, I know there has been an explosion recently of new ways to build object's in Perl 5, most of them based on inside-out objects and other such things. Moose is different because it is not a new object system for Perl 5, but instead an extension of the existing object system.

Moose is built on top of Class::MOP, which is a metaclass system for Perl 5. This means that Moose not only makes building normal Perl 5 objects better, but it also provides the power of metaclass programming.

Is this for real? Or is this just an experiment?

Moose is based on the prototypes and experiments I did for the Perl 6 meta-model. However, Moose is NOT an experiment/prototype; it is for real.

Is this ready for use in production?

Yes, I believe that it is.

Moose has been used successfully in production environemnts by several people and companies (including the one I work for). There are Moose applications which have been in production with little or no issue now for over a year. I consider it highly stable and we are commited to keeping it stable.

Of course, in the end, you need to make this call yourself. If you have any questions or concerns, please feel free to email me, or even the list or just stop by #moose and ask away.

Is Moose just Perl 6 in Perl 5?

No. While Moose is very much inspired by Perl 6, it is not itself Perl 6. Instead, it is an OO system for Perl 5. I built Moose because I was tired of writing the same old boring Perl 5 OO code, and drooling over Perl 6 OO. So instead of switching to Ruby, I wrote Moose :)

Moose Extensions

The MooseX:: namespace is the official place to find Moose extensions. There are a number of these modules out on CPAN right now the best way to find them is to search for MooseX:: on search.cpan.org.

BUILDING CLASSES WITH MOOSE

Moose makes every attempt to provide as much convenience as possible during class construction/definition, but still stay out of your way if you want it to. Here are a few items to note when building classes with Moose.

Unless specified with extends, any class which uses Moose will inherit from Moose::Object.

Moose will also manage all attributes (including inherited ones) that are defined with has. And (assuming you call new, which is inherited from Moose::Object) this includes properly initializing all instance slots, setting defaults where appropriate, and performing any type constraint checking or coercion.

EXPORTED FUNCTIONS

Moose will export a number of functions into the class's namespace which may then be used to set up the class. These functions all work directly on the current class.

meta

This is a method which provides access to the current class's metaclass.

extends (@superclasses)

This function will set the superclass(es) for the current class.

This approach is recommended instead of use base, because use base actually pushes onto the class's @ISA, whereas extends will replace it. This is important to ensure that classes which do not have superclasses still properly inherit from Moose::Object.

with (@roles)

This will apply a given set of @roles to the local class. Role support is currently under heavy development; see Moose::Role for more details.

has $name => %options

This will install an attribute of a given $name into the current class. The %options are the same as those provided by Class::MOP::Attribute, in addition to the list below which are provided by Moose (Moose::Meta::Attribute to be more specific):

is => 'rw'|'ro'

The is option accepts either rw (for read/write) or ro (for read only). These will create either a read/write accessor or a read-only accessor respectively, using the same name as the $name of the attribute.

If you need more control over how your accessors are named, you can use the reader, writer and accessor options inherited from Class::MOP::Attribute.

isa => $type_name

The isa option uses Moose's type constraint facilities to set up runtime type checking for this attribute. Moose will perform the checks during class construction, and within any accessors. The $type_name argument must be a string. The string may be either a class name or a type defined using Moose's type definition features. (Refer to Moose::Util::TypeConstraints for information on how to define a new type, and how to retrieve type meta-data).

coerce => (1|0)

This will attempt to use coercion with the supplied type constraint to change the value passed into any accessors or constructors. You must have supplied a type constraint in order for this to work. See Moose::Cookbook::Recipe5 for an example.

does => $role_name

This will accept the name of a role which the value stored in this attribute is expected to have consumed.

required => (1|0)

This marks the attribute as being required. This means a defined value must be supplied during class construction, and the attribute may never be set to undef with an accessor.

weak_ref => (1|0)

This will tell the class to store the value of this attribute as a weakened reference. If an attribute is a weakened reference, it cannot also be coerced.

lazy => (1|0)

This will tell the class to not create this slot until absolutely necessary. If an attribute is marked as lazy it must have a default supplied.

auto_deref => (1|0)

This tells the accessor whether to automatically dereference the value returned. This is only legal if your isa option is either ArrayRef or HashRef.

metaclass => $metaclass_name

This tells the class to use a custom attribute metaclass for this particular attribute. Custom attribute metaclasses are useful for extending the capabilities of the has keyword: they are the simplest way to extend the MOP, but they are still a fairly advanced topic and too much to cover here. I will try and write a recipe on them soon.

The default behavior here is to just load $metaclass_name; however, we also have a way to alias to a shorter name. This will first look to see if Moose::Meta::Attribute::Custom::$metaclass_name exists. If it does, Moose will then check to see if that has the method register_implemenetation, which should return the actual name of the custom attribute metaclass. If there is no register_implemenetation method, it will fall back to using Moose::Meta::Attribute::Custom::$metaclass_name as the metaclass name.

trigger => $code

The trigger option is a CODE reference which will be called after the value of the attribute is set. The CODE ref will be passed the instance itself, the updated value and the attribute meta-object (this is for more advanced fiddling and can typically be ignored). You cannot have a trigger on a read-only attribute.

handles => ARRAY | HASH | REGEXP | ROLE | CODE

The handles option provides Moose classes with automated delegation features. This is a pretty complex and powerful option. It accepts many different option formats, each with its own benefits and drawbacks.

NOTE: This feature is no longer experimental, but it may still have subtle bugs lurking in the deeper corners. If you think you have found a bug, you probably have, so please report it to me right away.

NOTE: The class being delegated to does not need to be a Moose based class, which is why this feature is especially useful when wrapping non-Moose classes.

All handles option formats share the following traits:

You cannot override a locally defined method with a delegated method; an exception will be thrown if you try. That is to say, if you define foo in your class, you cannot override it with a delegated foo. This is almost never something you would want to do, and if it is, you should do it by hand and not use Moose.

You cannot override any of the methods found in Moose::Object, or the BUILD and DEMOLISH methods. These will not throw an exception, but will silently move on to the next method in the list. My reasoning for this is that you would almost never want to do this, since it usually breaks your class. As with overriding locally defined methods, if you do want to do this, you should do it manually, not with Moose.

Below is the documentation for each option format:

ARRAY

This is the most common usage for handles. You basically pass a list of method names to be delegated, and Moose will install a delegation method for each one.

HASH

This is the second most common usage for handles. Instead of a list of method names, you pass a HASH ref where each key is the method name you want installed locally, and its value is the name of the original method in the class being delegated to.

This can be very useful for recursive classes like trees. Here is a quick example (soon to be expanded into a Moose::Cookbook::Recipe):

package Tree;
use Moose;

has 'node' => (is => 'rw', isa => 'Any');

has 'children' => (
    is      => 'ro',
    isa     => 'ArrayRef',
    default => sub { [] }
);

has 'parent' => (
    is          => 'rw',
    isa         => 'Tree',
    is_weak_ref => 1,
    handles     => {
        parent_node => 'node',
        siblings    => 'children',
    }
);

In this example, the Tree package gets parent_node and siblings methods, which delegate to the node and children methods (respectively) of the Tree instance stored in the parent slot.

REGEXP

The regexp option works very similar to the ARRAY option, except that it builds the list of methods for you. It starts by collecting all possible methods of the class being delegated to, then filters that list using the regexp supplied here.

NOTE: An isa option is required when using the regexp option format. This is so that we can determine (at compile time) the method list from the class. Without an isa this is just not possible.

ROLE

With the role option, you specify the name of a role whose "interface" then becomes the list of methods to handle. The "interface" can be defined as; the methods of the role and any required methods of the role. It should be noted that this does not include any method modifiers or generated attribute methods (which is consistent with role composition).

CODE

This is the option to use when you really want to do something funky. You should only use it if you really know what you are doing, as it involves manual metaclass twiddling.

This takes a code reference, which should expect two arguments. The first is the attribute meta-object this handles is attached to. The second is the metaclass of the class being delegated to. It expects you to return a hash (not a HASH ref) of the methods you want mapped.

has +$name => %options

This is variation on the normal attibute creator has which allows you to clone and extend an attribute from a superclass. Here is a quick example:

package Foo;
use Moose;

has 'message' => (
    is      => 'rw',
    isa     => 'Str',
    default => 'Hello, I am a Foo'
);

package My::Foo;
use Moose;

extends 'Foo';

has '+message' => (default => 'Hello I am My::Foo');

What is happening here is that My::Foo is cloning the message attribute from its parent class Foo, retaining the is => 'rw' and isa => 'Str' characteristics, but changing the value in default.

This feature is restricted somewhat, so as to try and force at least some sanity into it. You are only allowed to change the following attributes:

default: Change the default value of an attribute.
coerce: Change whether the attribute attempts to coerce a value passed to it.
required: Change if the attribute is required to have a value.
documentation: Change the documentation string associated with the attribute.
lazy: Change if the attribute lazily initializes the slot.
isa: You are allowed to change the type, if and only if the new type is a subtype of the old type.
handles: You are allowed to add a new handles definition, but you are not allowed to change one.

before $name|@names => sub { ... }

after $name|@names => sub { ... }

around $name|@names => sub { ... }

This three items are syntactic sugar for the before, after, and around method modifier features that Class::MOP provides. More information on these may be found in the Class::MOP::Class documentation for now.

super

The keyword super is a no-op when called outside of an override method. In the context of an override method, it will call the next most appropriate superclass method with the same arguments as the original method.

override ($name, &sub)

An override method is a way of explicitly saying "I am overriding this method from my superclass". You can call super within this method, and it will work as expected. The same thing can be accomplished with a normal method call and the SUPER:: pseudo-package; it is really your choice.

inner

The keyword inner, much like super, is a no-op outside of the context of an augment method. You can think of inner as being the inverse of super; the details of how inner and augment work is best described in the Moose::Cookbook.

augment ($name, &sub)

An augment method, is a way of explicitly saying "I am augmenting this method from my superclass". Once again, the details of how inner and augment work is best described in the Moose::Cookbook.

confess

This is the Carp::confess function, and exported here because I use it all the time. This feature may change in the future, so you have been warned.

blessed

This is the Scalar::Util::blessed function, it is exported here because I use it all the time. It is highly recommended that this is used instead of ref anywhere you need to test for an object's class name.

UNIMPORTING FUNCTIONS

unimport

Moose offers a way to remove the keywords it exports, through the unimport method. You simply have to say no Moose at the bottom of your code for this to work. Here is an example:

package Person;
use Moose;

has 'first_name' => (is => 'rw', isa => 'Str');
has 'last_name'  => (is => 'rw', isa => 'Str');

sub full_name {
    my $self = shift;
    $self->first_name . ' ' . $self->last_name
}

no Moose; # keywords are removed from the Person package

EXTENDING AND EMBEDDING MOOSE

Moose also offers some options for extending or embedding it into your own framework. The basic premise is to have something that sets up your class' metaclass and export the moose declarators (has, with, extends,...). Here is an example:

package MyFramework;
use Moose;

sub import {
    my $CALLER = caller();

    strict->import;
    warnings->import;

    # we should never export to main
    return if $CALLER eq 'main';
    Moose::init_meta( $CALLER, 'MyFramework::Base' );
    Moose->import({into => $CALLER});

    # Do my custom framework stuff

    return 1;
}

import

Moose's import method supports the Sub::Exporter form of {into => $pkg} and {into_level => 1}

init_meta ($class, $baseclass, $metaclass)

Moose does some boot strapping: it creates a metaclass object for your class, and then injects a meta accessor into your class to retrieve it. Then it sets your baseclass to Moose::Object or the value you pass in unless you already have one. This is all done via init_meta which takes the name of your class and optionally a baseclass and a metaclass as arguments.

CAVEATS

It should be noted that super and inner cannot be used in the same method. However, they may be combined within the same class hierarchy; see t/014_override_augment_inner_super.t for an example.

The reason for this is that super is only valid within a method with the override modifier, and inner will never be valid within an override method. In fact, augment will skip over any override methods when searching for its appropriate inner.

This might seem like a restriction, but I am of the opinion that keeping these two features separate (yet interoperable) actually makes them easy to use, since their behavior is then easier to predict. Time will tell whether I am right or not (UPDATE: so far so good).

ACKNOWLEDGEMENTS

I blame Sam Vilain for introducing me to the insanity that is meta-models.
I blame Audrey Tang for then encouraging my meta-model habit in #perl6.
Without Yuval "nothingmuch" Kogman this module would not be possible, and it certainly wouldn't have this name ;P
The basis of the TypeContraints module was Rob Kinyon's idea originally, I just ran with it.
Thanks to mst & chansen and the whole #moose poose for all the early ideas/feature-requests/encouragement/bug-finding.
Thanks to David "Theory" Wheeler for meta-discussions and spelling fixes.

BUGS

All complex software has bugs lurking in it, and this module is no exception. If you find a bug please either email me, or add the bug to cpan-RT.

AUTHOR

Stevan Little <stevan@iinteractive.com>

with contributions from:

Aankhen

Adam (Alias) Kennedy

Anders (Debolaz) Nor Berle

Nathan (kolibre) Gray

Christian (chansen) Hansen

Hans Dieter (confound) Pearcey

Eric (ewilhelm) Wilhelm

Guillermo (groditi) Roditi

Jess (castaway) Robinson

Matt (mst) Trout

Robert (phaylon) Sedlacek

Robert (rlb3) Boone

Scott (konobi) McWhirter

Shlomi (rindolf) Fish

Yuval (nothingmuch) Kogman

Chris (perigrin) Prather

Jonathan (jrockway) Rockway

Piotr (dexter) Roszatycki

Sam (mugwump) Vilain

... and many other #moose folks

COPYRIGHT AND LICENSE

http://www.iinteractive.com

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

To install Moose, copy and paste the appropriate command in to your terminal.

cpanm

cpanm Moose

CPAN shell

perl -MCPAN -e shell
install Moose

For more information on module installation, please visit the detailed CPAN module installation guide.

	Global
`s`	Focus search bar
`?`	Bring up this help dialog

	GitHub
`g` `p`	Go to pull requests
`g` `i`	go to github issues (only if github is preferred repository)

	POD
`g` `a`	Go to author
`g` `c`	Go to changes
`g` `i`	Go to issues
`g` `d`	Go to dist
`g` `r`	Go to repository/SCM
`g` `s`	Go to source
`g` `b`	Go to file browse

	Search terms
module: (e.g. module:Plugin)
distribution: (e.g. distribution:Dancer auth)
author: (e.g. author:SONGMU Redis)
version: (e.g. version:1.00)

NAME

SYNOPSIS

DESCRIPTION

Another object system!?!?

Is this for real? Or is this just an experiment?

Is this ready for use in production?

Is Moose just Perl 6 in Perl 5?

Moose Extensions

BUILDING CLASSES WITH MOOSE

EXPORTED FUNCTIONS

UNIMPORTING FUNCTIONS

unimport

EXTENDING AND EMBEDDING MOOSE

import

init_meta ($class, $baseclass, $metaclass)

CAVEATS

ACKNOWLEDGEMENTS

SEE ALSO

Papers

BUGS

AUTHOR

COPYRIGHT AND LICENSE

NAME

SYNOPSIS

DESCRIPTION

Another object system!?!?

Is this for real? Or is this just an experiment?

Is this ready for use in production?

Is Moose just Perl 6 in Perl 5?

Moose Extensions

BUILDING CLASSES WITH MOOSE

EXPORTED FUNCTIONS

UNIMPORTING FUNCTIONS

unimport

EXTENDING AND EMBEDDING MOOSE

import

init_meta ($class, $baseclass, $metaclass)

CAVEATS

ACKNOWLEDGEMENTS

SEE ALSO

Papers

BUGS

AUTHOR

COPYRIGHT AND LICENSE

Module Install Instructions