/ 
FAST-1.03
River stage zero No dependents
/ FAST::Bio::SeqIO

NAME

FAST::Bio::SeqIO - Handler for SeqIO Formats

SYNOPSIS

  use FAST::Bio::SeqIO;

  $in  = FAST::Bio::SeqIO->new(-file => "inputfilename" ,
                         -format => 'Fasta');
  $out = FAST::Bio::SeqIO->new(-file => ">outputfilename" ,
                         -format => 'EMBL');

  while ( my $seq = $in->next_seq() ) {
      $out->write_seq($seq);
  }

# Now, to actually get at the sequence object, use the standard FAST::Bio::Seq
# methods (look at FAST::Bio::Seq if you don't know what they are)

  use FAST::Bio::SeqIO;

  $in  = FAST::Bio::SeqIO->new(-file => "inputfilename" ,
                         -format => 'genbank');

  while ( my $seq = $in->next_seq() ) {
     print "Sequence ",$seq->id, " first 10 bases ",
           $seq->subseq(1,10), "\n";
  }


# The SeqIO system does have a filehandle binding. Most people find this
# a little confusing, but it does mean you can write the world's
# smallest reformatter

  use FAST::Bio::SeqIO;

  $in  = FAST::Bio::SeqIO->newFh(-file => "inputfilename" ,
                           -format => 'Fasta');
  $out = FAST::Bio::SeqIO->newFh(-format => 'EMBL');

  # World's shortest Fasta<->EMBL format converter:
  print $out $_ while <$in>;

DESCRIPTION

FAST::Bio::SeqIO is a handler module for the formats in the SeqIO set (eg, FAST::Bio::SeqIO::fasta). It is the officially sanctioned way of getting at the format objects, which most people should use.

The FAST::Bio::SeqIO system can be thought of like biological file handles. They are attached to filehandles with smart formatting rules (eg, genbank format, or EMBL format, or binary trace file format) and can either read or write sequence objects (FAST::Bio::Seq objects, or more correctly, FAST::Bio::SeqI implementing objects, of which FAST::Bio::Seq is one such object). If you want to know what to do with a FAST::Bio::Seq object, read FAST::Bio::Seq.

The idea is that you request a stream object for a particular format. All the stream objects have a notion of an internal file that is read from or written to. A particular SeqIO object instance is configured for either input or output. A specific example of a stream object is the FAST::Bio::SeqIO::fasta object.

Each stream object has functions

$stream->next_seq();

and

$stream->write_seq($seq);

As an added bonus, you can recover a filehandle that is tied to the SeqIO object, allowing you to use the standard <> and print operations to read and write sequence objects:

use FAST::Bio::SeqIO;

$stream = FAST::Bio::SeqIO->newFh(-format => 'Fasta',
                            -fh     => \*ARGV);
# read from standard input or the input filenames

while ( $seq = <$stream> ) {
    # do something with $seq
}

and

print $stream $seq; # when stream is in output mode

This makes the simplest ever reformatter

#!/usr/bin/perl
use strict;
my $format1 = shift;
my $format2 = shift || die
   "Usage: reformat format1 format2 < input > output";

use FAST::Bio::SeqIO;

my $in  = FAST::Bio::SeqIO->newFh(-format => $format1, -fh => \*ARGV );
my $out = FAST::Bio::SeqIO->newFh(-format => $format2 );
# Note: you might want to quote -format to keep older
# perl's from complaining.

print $out $_ while <$in>;

CONSTRUCTORS

FAST::Bio::SeqIO->new()

$seqIO = FAST::Bio::SeqIO->new(-file => 'filename',   -format=>$format);
$seqIO = FAST::Bio::SeqIO->new(-fh   => \*FILEHANDLE, -format=>$format);
$seqIO = FAST::Bio::SeqIO->new(-format => $format);

The new() class method constructs a new FAST::Bio::SeqIO object. The returned object can be used to retrieve or print Seq objects. new() accepts the following parameters:

-file

A file path to be opened for reading or writing. The usual Perl conventions apply:

'file'       # open file for reading
'>file'      # open file for writing
'>>file'     # open file for appending
'+<file'     # open file read/write
'command |'  # open a pipe from the command
'| command'  # open a pipe to the command
-fh

You may provide new() with a previously-opened filehandle. For example, to read from STDIN:

$seqIO = FAST::Bio::SeqIO->new(-fh => \*STDIN);

Note that you must pass filehandles as references to globs.

If neither a filehandle nor a filename is specified, then the module will read from the @ARGV array or STDIN, using the familiar <> semantics.

A string filehandle is handy if you want to modify the output in the memory, before printing it out. The following program reads in EMBL formatted entries from a file and prints them out in fasta format with some HTML tags:

use FAST::Bio::SeqIO;
use IO::String;
my $in  = FAST::Bio::SeqIO->new(-file => "emblfile",
                          -format => 'EMBL');
while ( my $seq = $in->next_seq() ) {
    # the output handle is reset for every file
    my $stringio = IO::String->new($string);
    my $out = FAST::Bio::SeqIO->new(-fh => $stringio,
                              -format => 'fasta');
    # output goes into $string
    $out->write_seq($seq);
    # modify $string
    $string =~ s|(>)(\w+)|$1<font color="Red">$2</font>|g;
    # print into STDOUT
    print $string;
}
-format

Specify the format of the file. Supported formats include fasta, genbank, embl, swiss (SwissProt), Entrez Gene and tracefile formats such as abi (ABI) and scf. There are many more, for a complete listing see the SeqIO HOWTO (http://bioperl.open-bio.org/wiki/HOWTO:SeqIO).

If no format is specified and a filename is given then the module will attempt to deduce the format from the filename suffix. If there is no suffix that Bioperl understands then it will attempt to guess the format based on file content. If this is unsuccessful then SeqIO will throw a fatal error.

The format name is case-insensitive: 'FASTA', 'Fasta' and 'fasta' are all valid.

Currently, the tracefile formats (except for SCF) require installation of the external Staden "io_lib" package, as well as the FAST::Bio::SeqIO::staden::read package available from the bioperl-ext repository.

-alphabet

Sets the alphabet ('dna', 'rna', or 'protein'). When the alphabet is set then Bioperl will not attempt to guess what the alphabet is. This may be important because Bioperl does not always guess correctly.

-flush

By default, all files (or filehandles) opened for writing sequences will be flushed after each write_seq() (making the file immediately usable). If you do not need this facility and would like to marginally improve the efficiency of writing multiple sequences to the same file (or filehandle), pass the -flush option '0' or any other value that evaluates as defined but false:

my $gb = FAST::Bio::SeqIO->new(-file   => "<gball.gbk",
                         -format => "gb");
my $fa = FAST::Bio::SeqIO->new(-file   => ">gball.fa",
                         -format => "fasta",
                         -flush  => 0); # go as fast as we can!
while($seq = $gb->next_seq) { $fa->write_seq($seq) }
-seqfactory

Provide a FAST::Bio::Factory::SequenceFactoryI object. See the sequence_factory() method.

-locfactory

Provide a FAST::Bio::Factory::LocationFactoryI object. See the location_factory() method.

-objbuilder

Provide a FAST::Bio::Factory::ObjectBuilderI object. See the object_builder() method.

FAST::Bio::SeqIO->newFh()

$fh = FAST::Bio::SeqIO->newFh(-fh => \*FILEHANDLE, -format=>$format);
$fh = FAST::Bio::SeqIO->newFh(-format => $format);
# etc.

This constructor behaves like new(), but returns a tied filehandle rather than a FAST::Bio::SeqIO object. You can read sequences from this object using the familiar <> operator, and write to it using print(). The usual array and $_ semantics work. For example, you can read all sequence objects into an array like this:

@sequences = <$fh>;

Other operations, such as read(), sysread(), write(), close(), and printf() are not supported.

OBJECT METHODS

See below for more detailed summaries. The main methods are:

$sequence = $seqIO->next_seq()

Fetch the next sequence from the stream, or nothing if no more.

$seqIO->write_seq($sequence [,$another_sequence,...])

Write the specified sequence(s) to the stream.

TIEHANDLE(), READLINE(), PRINT()

These provide the tie interface. See perltie for more details.

FEEDBACK

Mailing Lists

User feedback is an integral part of the evolution of this and other Bioperl modules. Send your comments and suggestions preferably to one of the Bioperl mailing lists.

Your participation is much appreciated.

bioperl-l@bioperl.org                  - General discussion
http://bioperl.org/wiki/Mailing_lists  - About the mailing lists

Support

Please direct usage questions or support issues to the mailing list:

bioperl-l@bioperl.org

rather than to the module maintainer directly. Many experienced and responsive experts will be able look at the problem and quickly address it. Please include a thorough description of the problem with code and data examples if at all possible.

Reporting Bugs

Report bugs to the Bioperl bug tracking system to help us keep track the bugs and their resolution. Bug reports can be submitted via the web:

https://redmine.open-bio.org/projects/bioperl/

AUTHOR - Ewan Birney, Lincoln Stein

Email birney@ebi.ac.uk lstein@cshl.org

APPENDIX

The rest of the documentation details each of the object methods. Internal methods are usually preceded with a _

new

Title   : new
Usage   : $stream = FAST::Bio::SeqIO->new(-file => 'sequences.fasta',
                                    -format => 'fasta');
Function: Returns a new sequence stream
Returns : A FAST::Bio::SeqIO stream initialised with the appropriate format
Args    : Named parameters:
            -file   => filename
            -fh     => filehandle to attach to
            -format => format

          Additional arguments may be used. They all have reasonable defaults
          and are thus optional.
            -alphabet   => 'dna', 'rna', or 'protein'
            -flush      => 0 or 1 (default, flush filehandles after each write)
            -seqfactory => sequence factory
            -locfactory => location factory
            -objbuilder => object builder

See FAST::Bio::SeqIO::Handler

newFh

Title   : newFh
Usage   : $fh = FAST::Bio::SeqIO->newFh(-file=>$filename,-format=>'Format')
Function: Does a new() followed by an fh()
Example : $fh = FAST::Bio::SeqIO->newFh(-file=>$filename,-format=>'Format')
          $sequence = <$fh>;   # read a sequence object
          print $fh $sequence; # write a sequence object
Returns : filehandle tied to the FAST::Bio::SeqIO::Fh class
Args    :

See FAST::Bio::SeqIO::Fh

fh

Title   : fh
Usage   : $obj->fh
Function: Get or set the IO filehandle
Example : $fh = $obj->fh;      # make a tied filehandle
          $sequence = <$fh>;   # read a sequence object
          print $fh $sequence; # write a sequence object
Returns : filehandle tied to FAST::Bio::SeqIO class
Args    : none

next_seq

Title   : next_seq
Usage   : $seq = stream->next_seq
Function: Reads the next sequence object from the stream and returns it.

          Certain driver modules may encounter entries in the stream
          that are either misformatted or that use syntax not yet
          understood by the driver. If such an incident is
          recoverable, e.g., by dismissing a feature of a feature
          table or some other non-mandatory part of an entry, the
          driver will issue a warning. In the case of a
          non-recoverable situation an exception will be thrown.  Do
          not assume that you can resume parsing the same stream
          after catching the exception. Note that you can always turn
          recoverable errors into exceptions by calling
          $stream->verbose(2).

Returns : a FAST::Bio::Seq sequence object, or nothing if no more sequences
          are available

Args    : none

See FAST::Bio::Root::RootI, FAST::Bio::Factory::SeqStreamI, FAST::Bio::Seq

write_seq

Title   : write_seq
Usage   : $stream->write_seq($seq)
Function: writes the $seq object into the stream
Returns : 1 for success and 0 for error
Args    : FAST::Bio::Seq object

format

Title   : format
Usage   : $format = $stream->format()
Function: Get the sequence format
Returns : sequence format, e.g. fasta, fastq
Args    : none

alphabet

Title   : alphabet
Usage   : $self->alphabet($newval)
Function: Set/get the molecule type for the Seq objects to be created.
Example : $seqio->alphabet('protein')
Returns : value of alphabet: 'dna', 'rna', or 'protein'
Args    : newvalue (optional)
Throws  : Exception if the argument is not one of 'dna', 'rna', or 'protein'

_load_format_module

Title   : _load_format_module
Usage   : *INTERNAL SeqIO stuff*
Function: Loads up (like use) a module at run time on demand
Example :
Returns :
Args    :

_concatenate_lines

Title   : _concatenate_lines
Usage   : $s = _concatenate_lines($line, $continuation_line)
Function: Private. Concatenates two strings assuming that the second stems
          from a continuation line of the first. Adds a space between both
          unless the first ends with a dash.

          Takes care of either arg being empty.
Example :
Returns : A string.
Args    :

_filehandle

Title   : _filehandle
Usage   : $obj->_filehandle($newval)
Function: This method is deprecated. Call _fh() instead.
Example :
Returns : value of _filehandle
Args    : newvalue (optional)

_guess_format

Title   : _guess_format
Usage   : $obj->_guess_format($filename)
Function: guess format based on file suffix
Example :
Returns : guessed format of filename (lower case)
Args    :
Notes   : formats that _filehandle() will guess include fasta,
          genbank, scf, pir, embl, raw, gcg, ace, bsml, swissprot,
          fastq and phd/phred

sequence_factory

Title   : sequence_factory
Usage   : $seqio->sequence_factory($seqfactory)
Function: Get/Set the FAST::Bio::Factory::SequenceFactoryI
Returns : FAST::Bio::Factory::SequenceFactoryI
Args    : [optional] FAST::Bio::Factory::SequenceFactoryI

object_factory

Title   : object_factory
Usage   : $obj->object_factory($newval)
Function: This is an alias to sequence_factory with a more generic name.
Example :
Returns : value of object_factory (a scalar)
Args    : on set, new value (a scalar or undef, optional)

sequence_builder

Title   : sequence_builder
Usage   : $seqio->sequence_builder($seqfactory)
Function: Get/Set the FAST::Bio::Factory::ObjectBuilderI used to build sequence
          objects. This applies to rich sequence formats only, e.g. genbank
          but not fasta.

          If you do not set the sequence object builder yourself, it
          will in fact be an instance of L<FAST::Bio::Seq::SeqBuilder>, and
          you may use all methods documented there to configure it.

Returns : a FAST::Bio::Factory::ObjectBuilderI compliant object
Args    : [optional] a FAST::Bio::Factory::ObjectBuilderI compliant object

location_factory

Title   : location_factory
Usage   : $seqio->location_factory($locfactory)
Function: Get/Set the FAST::Bio::Factory::LocationFactoryI object to be used for
          location string parsing
Returns : a FAST::Bio::Factory::LocationFactoryI implementing object
Args    : [optional] on set, a FAST::Bio::Factory::LocationFactoryI implementing
          object.